sci-physics/clhep: version bump to 2.4.1.2

Package-Manager: Portage-2.3.67, Repoman-2.3.16
Signed-off-by: Guilherme Amadio <amadio@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/sci-physics/clhep/clhep-2.4.1.2.ebuild b/sci-physics/clhep/clhep-2.4.1.2.ebuild
new file mode 100644
index 000000000000..8eac6ef22dd0
--- /dev/null
+++ b/sci-physics/clhep/clhep-2.4.1.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="High Energy Physics C++ library"
+HOMEPAGE="http://proj-clhep.web.cern.ch/proj-clhep/"
+SRC_URI="http://proj-clhep.web.cern.ch/proj-clhep/dist1/${P}.tgz"
+LICENSE="GPL-3 LGPL-3"
+SLOT="2/${PV}"
+KEYWORDS="~amd64 ~hppa ~ppc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+IUSE="doc test threads"
+
+BDEPEND="doc? ( app-doc/doxygen[latex] )"
+
+S="${WORKDIR}/${PV}/CLHEP"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# respect flags
+	sed -i -e 's:-O::g' cmake/Modules/ClhepVariables.cmake || die
+	# dont build test if not asked
+	if ! use test; then
+		sed -i \
+			-e '/add_subdirectory(test)/d' \
+			*/CMakeLists.txt || die
+	fi
+	# gentoo doc directory
+	if use doc; then
+		grep -rl 'share/doc/CLHEP' |
+		xargs sed -i \
+			-e "s:share/doc/CLHEP:share/doc/${PF}:" \
+			{.,*}/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCLHEP_BUILD_DOCS=$(usex doc)
+		-DCLHEP_SINGLE_THREAD=$(usex threads no yes)
+	)
+	DESTDIR="${ED}" cmake-utils_src_configure
+}