sci-visualization/gr: Version bump

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/sci-visualization/gr/Manifest b/sci-visualization/gr/Manifest
index 5101eb04b361..e71fd8144380 100644
--- a/sci-visualization/gr/Manifest
+++ b/sci-visualization/gr/Manifest
@@ -1 +1,2 @@
 DIST gr-0.50.0.tar.gz 8612608 BLAKE2B 70f4a3c6ce1dac8556646a1632667e6e464a5048f3c44fb689709e3e8218e8d7375db6ff8ce73e11dbeda559fb27c83b7f2b42f0ab518df9b464c8443748c30e SHA512 34ca077ae729e6eda0e5df7046811c77d717f3ef0e34203d6ab3a7f4b67b3aa058a68b9b2d7d78adc8b2f0830a0298778198a6499bd3d6e5697e4b7270cb648a
+DIST gr-0.53.0.tar.gz 19267451 BLAKE2B bd243fac9df6222c4b9e3591adfcd1d37dd41628719bd7be7ab385402f0f97e21f3eb23df3ae5d2ed3e43df2b3d83ff66f4e0b478d717772b57dce5885a98721 SHA512 49eee39fd4abd62d6794a16eb023688a525f6906054610dccd85c1b7b0bed9b198d923834cbf661099f753ec40b383a911c295f781420aeead712c5712583c80
diff --git a/sci-visualization/gr/gr-0.53.0.ebuild b/sci-visualization/gr/gr-0.53.0.ebuild
new file mode 100644
index 000000000000..dbdaaca1611b
--- /dev/null
+++ b/sci-visualization/gr/gr-0.53.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2019-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Universal framework for cross-platform visualization applications"
+HOMEPAGE="https://gr-framework.org/"
+SRC_URI="https://github.com/sciapp/gr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cairo ffmpeg postscript tiff truetype"
+
+DEPEND="
+	dev-qt/qtgui:5
+	media-libs/fontconfig
+	media-libs/glfw
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:=
+	media-libs/qhull:=
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXt
+	cairo? ( x11-libs/cairo )
+	ffmpeg? ( media-video/ffmpeg:= )
+	postscript? ( app-text/ghostscript-gpl )
+	tiff? ( media-libs/tiff )
+	truetype? ( media-libs/freetype )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+src_configure() {
+	use cairo || mycmakeargs+=( -DCAIRO_LIBRARY= )
+	use postscript || mycmakeargs+=( -DGS_LIBRARY= )
+	use ffmpeg || mycmakeargs+=( -DFFMPEG_INCLUDE_DIR= )
+	use truetype || mycmakeargs+=( -DFREETYPE_LIBRARY= )
+	use tiff || mycmakeargs+=( -DTIFF_LIBRARY= )
+
+	# todo: X11 automagic
+
+	mycmakeargs+=( -DCMAKE_INSTALL_PREFIX=/usr/gr )
+	#
+	# I need to have a serious conversation with upstream.
+	# * The main consumer of this package is dev-lang/julia.
+	# * If I patch gr to install in standard locations, julia does
+	#   not find it anymore.
+	# * I can't patch julia, since the corresponding scripts are
+	#   downloaded at runtime from its package registry ...
+	#
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	find "${ED}" -name '*.a' -delete
+
+	echo "GRDIR=/usr/gr" > "${T}/99gr"
+	echo "LDPATH=/usr/gr/$(get_libdir)" >> "${T}/99gr"
+	doenvd "${T}/99gr"
+
+	[[ -f "${ED}/usr/gr/bin/gksqt" ]] && dosym ../gr/bin/gksqt /usr/bin/gksqt
+
+	elog "${P} relies on the environment variable GRDIR. If you want to use it in a running shell,"
+	elog "e.g. with dev-lang/julia, then run \"source /etc/profile\" first."
+}