sys-apps/s6: add 2.11.3.0

The package newly installs libraries to /lib* rather than /usr/lib*
because utilities are installed to /bin, therefore, they should link
shared libraries from /lib*.

The /lib/s6 destination is used helper utilities instead of
/usr/libexec.

See-also: https://github.com/gentoo/gentoo/pull/12120#discussion_r296437625
Signed-off-by: Petr Vaněk <arkamar@atlas.cz>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/sys-apps/s6/s6-2.11.3.0.ebuild b/sys-apps/s6/s6-2.11.3.0.ebuild
new file mode 100644
index 000000000000..589e48f8ebb4
--- /dev/null
+++ b/sys-apps/s6/s6-2.11.3.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="skarnet.org's small and secure supervision software suite"
+HOMEPAGE="https://www.skarnet.org/software/s6/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~riscv ~x86"
+IUSE="+execline"
+
+RDEPEND="
+	>=dev-libs/skalibs-2.13.1.0:=
+	execline? ( dev-lang/execline:= )
+"
+DEPEND="${RDEPEND}"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
+
+	sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local myconf=(
+		--bindir=/bin
+		--dynlibdir="/$(get_libdir)"
+		--libdir="/usr/$(get_libdir)/${PN}"
+		--libexecdir=/lib/s6
+		--with-dynlib="/$(get_libdir)"
+		--with-lib="/usr/$(get_libdir)/execline"
+		--with-lib="/usr/$(get_libdir)/skalibs"
+		--with-sysdeps="/usr/$(get_libdir)/skalibs"
+		--enable-shared
+		--disable-allstatic
+		--disable-static
+		--disable-static-libc
+		$(use_enable execline)
+	)
+
+	econf "${myconf[@]}"
+}