sys-auth/ssh-ldap-pubkey: Revbump to change dependency

Non-maintainer commit
pyldap is now part of python-ldap-3.0 and deprecated as a project

Tests pass

Bug: https://bugs.gentoo.org/668066
Signed-off-by: Brian Evans <grknight@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 69 insertions, 0 deletions

diff --git a/sys-auth/ssh-ldap-pubkey/ssh-ldap-pubkey-1.3.0-r1.ebuild b/sys-auth/ssh-ldap-pubkey/ssh-ldap-pubkey-1.3.0-r1.ebuild
new file mode 100644
index 000000000000..628ee8f4f193
--- /dev/null
+++ b/sys-auth/ssh-ldap-pubkey/ssh-ldap-pubkey-1.3.0-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+inherit distutils-r1
+
+DESCRIPTION="Utility to manage SSH public keys stored in LDAP"
+HOMEPAGE="https://github.com/jirutka/ssh-ldap-pubkey"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/jirutka/${PN}/${PN}.git"
+
+	inherit git-r3
+else
+	SRC_URI="https://github.com/jirutka/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+MY_CDEPEND="
+	dev-python/docopt[${PYTHON_USEDEP}]
+	>=dev-python/python-ldap-3.0[${PYTHON_USEDEP}]
+	virtual/logger"
+
+DEPEND="
+	${MY_CDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-describe[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)"
+
+# We need to block previous net-misc/openssh packages
+# to avoid file collision on "/etc/openldap/schema/openssh-lpk.schema"
+RDEPEND="${MY_CDEPEND}
+	!net-misc/openssh[ldap]"
+
+DOCS=( README.md CHANGELOG.adoc )
+
+src_prepare() {
+	sed -i -e 's/pyldap/python-ldap >= 3.0/' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	pytest -vv || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/openldap/schema
+	doins etc/openssh-lpk.schema
+
+	local MY_DOCDIR="/usr/share/doc/${PF}/examples"
+	insinto "${MY_DOCDIR}"
+	doins etc/ldap.conf
+
+	# We don't want to compress this small file to allow user
+	# to diff configuration against upstream's default
+	docompress -x "${MY_DOCDIR}"
+}