sys-kernel/gentoo-kernel-bin: bump to 5.11.5 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 86d47708b3ec..fb71471348cb 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -50,6 +50,7 @@ DIST gentoo-kernel-5.11.4-1.amd64.xpak 64915116 BLAKE2B b7fac7ed149cac31c3bb670f
 DIST gentoo-kernel-5.11.4-1.arm64.xpak 59923833 BLAKE2B fbafa63cd0414d2536bec17304fb66b3ffadb3ee3e43a23210b8a10f3a9eda390a011e7b59ac2d741428761d28f2eb002683048b0d68ea5775a32957d3098500 SHA512 831324ff10470f0920652c7451267b7933204f02bb379ad3354b107df0d5e39ac561a6d8b020d7def081083f05ba9c3e91d6643536f437e3fc8ed74f10a1bb98
 DIST gentoo-kernel-5.11.4-1.x86.xpak 57890628 BLAKE2B 53a80025da8ccd72921e21ddb16538f111b953c9cdafdb791b26b926e3ffacce76eec7850bb2f72c6b721b89aa617e33f4e49822600d294293d7d0b2b0bdd4e5 SHA512 39864af55c3e8a4d07702de0db922e28c176841e9c7599251acdd67c55820bec940eff29867f0eb9161367f8d0362a7bcf7f99a14b2b36709e76aed1709e0a75
 DIST gentoo-kernel-5.11.5-1.amd64.xpak 64924579 BLAKE2B b4484bb69d8355f63acecadac5a604ab57f61ae87a4341cba16c6b3cdc35d19c64c6d8042fedc69aa1272c151d09ba5957b9b26f2a6ab067a46451fd0a928b9b SHA512 218d649adc456f13055e7ec7ce3de1ead2cfdcc41d6d5d023de67dcc7a21679154dfe057dcf72592ab7a7315a8cf1a4d7a96f7904c21f0f8e219f3a277dae21f
+DIST gentoo-kernel-5.11.5-1.arm64.xpak 59869818 BLAKE2B 26d4431d1e9e3dd58f1d352ab872cf2749d64ae768a114d42cf1bf3ac342c9792dfa19ccd1bf502ea26ee99a0bb00e75783b2958726d5073d8f69c3f66e29a9c SHA512 ea64669b86cb1a3c86f92016f8a9838eabf1328c9a996084c8e8226b736d526b7d246f42d24ff9d07d2d0606cc0db914251b7007caa74080a482c0bcdd4a0bc6
 DIST gentoo-kernel-5.11.5-1.x86.xpak 57891193 BLAKE2B f9f1eed75c7a81067994fe07a8305e5d70001c4ac969ae4d39d222960cf70c5fe5591db0a4e19fbaca9faa53e6dc1206158c0ad071cf3907761a61b00eedf098 SHA512 9494f10ae5a2ad3a0232e9eca5cb16647e4967f5ded3b45b5752f2e380b1c21437b9239d2fc7336cd84a246b488dc405e389c844263834a1feeea9257b2f8779
 DIST gentoo-kernel-5.4.100-1.amd64.xpak 61080710 BLAKE2B 84b33a1aa252b0957eb90ddd792f001942589d7f65399a5b007a2c831d0a1fa3b879814a55e5cf8b1ad6166970d3ac89838f57a2c61cec6b7b136b55d5ea4c7b SHA512 98b3dfd31a2830ed49dfc7094e9f37a39e7fbef54b648b4840122f2b53b8e970fb9c75a653445753d8e4efbd723716b9c56b2f99214c79832f3e49de63b3efbe
 DIST gentoo-kernel-5.4.100-1.arm64.xpak 56394488 BLAKE2B b8ea7a56a087e98706099cc151b652dba2a40e2a39ae99670b0989ce2f11c133f07b53dda1a9749f946719ab8a5b97a57ee0a12fcf3d9a568b498859420eeef5 SHA512 549ada0acf8874d3254c8a586f5c4d0ed4f08a103aee74befae38fc47d10c716d86f3f133b8ee3c49e61fcacda2298b04b5fe96bf35917b0963f922fe424e96f
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.5-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.5-r1.ebuild
new file mode 100644
index 000000000000..1d8f27f26279
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.5-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${PV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${PV}" \
+		"usr/src/linux-${PV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${PV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${PV}"/ || die
+}