proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 66 insertions, 0 deletions

diff --git a/sys-power/nvclock/nvclock-0.8_p20110102-r2.ebuild b/sys-power/nvclock/nvclock-0.8_p20110102-r2.ebuild
new file mode 100644
index 000000000000..b9e7d5978e5c
--- /dev/null
+++ b/sys-power/nvclock/nvclock-0.8_p20110102-r2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+inherit autotools eutils
+
+DESCRIPTION="NVIDIA Overclocking Utility"
+HOMEPAGE="http://www.linuxhardware.org/nvclock/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ppc x86"
+IUSE="gtk nvcontrol"
+
+RDEPEND="
+	gtk? (
+		x11-libs/gtk+:2
+		x11-libs/libX11
+	)
+	nvcontrol? ( x11-libs/libX11 x11-libs/libXext )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-r1-make.patch \
+		"${FILESDIR}"/${P}-usleep.patch \
+		"${FILESDIR}"/${P}-desktop.patch \
+		"${FILESDIR}"/${P}-buffers.patch
+	eautoreconf
+}
+
+src_configure() {
+	sed -i \
+		-e "/^AR=ar/s:=.*:=$(tc-getAR):" \
+		src/*/Makefile.in || die
+
+	# Qt support would mean Qt 3.
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--disable-qt \
+		$(use_enable gtk) \
+		$(use_enable nvcontrol)
+}
+
+src_compile() {
+	emake -C src/ nvclock smartdimmer
+	use gtk && emake -C src/gtk/
+}
+
+src_install() {
+	mkdir -p "${D}"/usr/bin || die
+
+	default
+
+	newinitd "${FILESDIR}"/nvclock_initd nvclock
+	newconfd "${FILESDIR}"/nvclock_confd nvclock
+}
+
+pkg_postinst() {
+	elog "To enable card overclocking at startup, edit your /etc/conf.d/nvclock"
+	elog "accordingly and then run: rc-update add nvclock default"
+}