www-client/opera-developer: bump to 75.0.3925.0

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 140 insertions, 0 deletions

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index 29106bb40320..a9a2c89ba0dd 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,2 +1,3 @@
 DIST opera-developer_74.0.3904.0_amd64.deb 72559240 BLAKE2B 566cecf54030e461a4af514e92945897444f67afbd87e9388a0a4cb9a2844b86555e254abb10ac6370ddebda095a7ded396a6312098d337838ef50f2ca2c705a SHA512 fb094d5002c413fc448716ab4aacb5d4a1389890f62c700f29bf75de1cf97e15750d3b8dfc670387fd759c4985d7c2128c1e0df9e32109cb2e9b71223cc7ee26
+DIST opera-developer_75.0.3925.0_amd64.deb 73581348 BLAKE2B 06eb0592c92c07cd6eaf0dd06683f355f77b96bf34a3cabd64176cf7bafe0a760b41f27fbe4969b93d5d9ee67a91bdff0bb93c4fdab33de7e38f690fbc8b8d99 SHA512 f86785066ec6508a633c8612a271443a2f463c2e124a205477e06195c8c802e742e5a58565674dec07221115289f2ed79b0ab38bd8e2d94970e70679986fb2d3
 DIST opera-ffmpeg-codecs-88.0.4324.27.tar.xz 1362668 BLAKE2B 0815049dbf95996a04a072ad1b82664ef594e0ea99aaea5ea9d54448457bb5aa5c6d9cb95d6c84a14ca64a29e0a2e9c6f5315a1988eb577ad02cc7422fe0f886 SHA512 cd1857d302c413a52433839103a3a268a12ab255ad8d6e651e872f7f28b61e1426e3c2854fc9a6acf4430be9fa8fea939de288c800cc3c60696394f77d86146d
diff --git a/www-client/opera-developer/opera-developer-75.0.3925.0.ebuild b/www-client/opera-developer/opera-developer-75.0.3925.0.ebuild
new file mode 100644
index 000000000000..64ec47298648
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-75.0.3925.0.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib pax-utils unpacker xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	KEYWORDS="-* amd64"
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	KEYWORDS="-* ~amd64"
+	MY_PN=${PN}
+fi
+
+FFMPEG_VERSION="88.0.4324.27"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}
+	proprietary-codecs? (
+		https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid widevine"
+RESTRICT="bindist mirror"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa[gbm]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	widevine? ( www-plugins/chrome-binary-plugins )
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	unpacker
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	rm -r "usr/share/lintian" || die
+
+	# fix docs
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gzip -d usr/share/doc/${PF}/changelog.gz || die
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# symlink widevine
+	rm "${OPERA_HOME}/resources/widevine_config.json" || die
+	if use widevine; then
+		echo "[\"${EPREFIX}/usr/$(get_libdir)/chromium-browser/WidevineCdm\"]" > \
+			"${OPERA_HOME}/resources/widevine_config.json" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}