x11-base/xwayland: Version bump to 23.1.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 108 insertions, 5 deletions

diff --git a/x11-base/xwayland/Manifest b/x11-base/xwayland/Manifest
index 87a4500a57f1..c0062184b886 100644
--- a/x11-base/xwayland/Manifest
+++ b/x11-base/xwayland/Manifest
@@ -1 +1,2 @@
 DIST xwayland-22.1.8.tar.xz 1273668 BLAKE2B ad1f3e0a6a3782b271653864380d0beb0db60293fb96ab8f218caaeef245967ad46ca505fb516a936115c9d49e6a32bffb725bc6c95dc98a6c4c24521c6022df SHA512 f52c6f99d8ef7605bc1c651d5ee5e306c12af30649a2d712b1c4c3cf4c7c80246ae24bd9ac39461d47aafc78f5d659446a459cd6259e05ef3128b204981d114a
+DIST xwayland-23.1.0.tar.xz 1286056 BLAKE2B 19f3cee10f9b86a1ee4529f91de3125c303a771ddb00ab1d76764fec2d8d2639e20585de777741fc3706ec6e2f03a1295024cd9c582c1e4a744fa1a43d8997e6 SHA512 984213a193b903e6023ecb3144a15f483dc3e9ec7cb02c36d8e67c6859b501b8b3e5a6e1ade9cb245450ad93002322f392b81d9286377ac34350cc3ea1f9679f
diff --git a/x11-base/xwayland/xwayland-23.1.0.ebuild b/x11-base/xwayland/xwayland-23.1.0.ebuild
new file mode 100644
index 000000000000..d7e53ec8adcf
--- /dev/null
+++ b/x11-base/xwayland/xwayland-23.1.0.ebuild
@@ -0,0 +1,101 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/xorg/xserver.git"
+	inherit git-r3
+else
+	SRC_URI="https://xorg.freedesktop.org/archive/individual/xserver/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="Standalone X server running under Wayland"
+HOMEPAGE="https://wayland.freedesktop.org/xserver.html"
+
+IUSE="selinux video_cards_nvidia unwind xcsecurity"
+
+LICENSE="MIT"
+SLOT="0"
+
+COMMON_DEPEND="
+	dev-libs/libbsd
+	dev-libs/openssl:=
+	>=dev-libs/wayland-1.21.0
+	>=dev-libs/wayland-protocols-1.28
+	media-fonts/font-util
+	>=media-libs/libepoxy-1.5.4[X,egl(+)]
+	media-libs/libglvnd[X]
+	>=media-libs/mesa-21.1[X(+),egl(+),gbm(+)]
+	>=x11-libs/libdrm-2.4.109
+	>=x11-libs/libXau-1.0.4
+	x11-libs/libxcvt
+	>=x11-libs/libXdmcp-1.0.2
+	>=x11-libs/libXfont2-2.0.1
+	x11-libs/libxkbfile
+	>=x11-libs/libxshmfence-1.1
+	>=x11-libs/pixman-0.27.2
+	>=x11-misc/xkeyboard-config-2.4.1-r3
+
+	unwind? ( sys-libs/libunwind )
+	video_cards_nvidia? ( gui-libs/egl-wayland )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	>=x11-base/xorg-proto-2022.2
+	>=x11-libs/xtrans-1.3.5
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-apps/xkbcomp
+	!<=x11-base/xorg-server-1.20.11
+	selinux? ( sec-policy/selinux-xserver )
+"
+BDEPEND="
+	sys-devel/flex
+	dev-util/wayland-scanner
+"
+
+PATCHES=(
+	"${FILESDIR}"/xwayland-drop-redundantly-installed-files.patch
+)
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use selinux xselinux)
+		$(meson_use unwind libunwind)
+		$(meson_use xcsecurity)
+		$(meson_use video_cards_nvidia xwayland_eglstream)
+		-Ddpms=true
+		-Ddri3=true
+		-Ddrm=true
+		-Ddtrace=false
+		-Dglamor=true
+		-Dglx=true
+		-Dipv6=true
+		-Dsecure-rpc=false
+		-Dscreensaver=true
+		-Dsha1=libcrypto
+		-Dxace=true
+		-Dxdmcp=true
+		-Dxinerama=true
+		-Dxvfb=true
+		-Dxv=true
+		-Dxwayland-path="${EPREFIX}"/usr/bin
+		-Dlibdecor=false
+		-Ddocs=false
+		-Ddevel-docs=false
+		-Ddocs-pdf=false
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	dosym ../bin/Xwayland /usr/libexec/Xwayland
+
+	meson_src_install
+}
diff --git a/x11-base/xwayland/xwayland-9999.ebuild b/x11-base/xwayland/xwayland-9999.ebuild
index beed9ee6c40c..cd8c1b8fb8d2 100644
--- a/x11-base/xwayland/xwayland-9999.ebuild
+++ b/x11-base/xwayland/xwayland-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2021-2022 Gentoo Authors
+# Copyright 2021-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -24,13 +24,13 @@ SLOT="0"
 COMMON_DEPEND="
 	dev-libs/libbsd
 	dev-libs/openssl:=
-	>=dev-libs/wayland-1.20
-	>=dev-libs/wayland-protocols-1.22
+	>=dev-libs/wayland-1.21.0
+	>=dev-libs/wayland-protocols-1.28
 	media-fonts/font-util
 	>=media-libs/libepoxy-1.5.4[X,egl(+)]
 	media-libs/libglvnd[X]
 	>=media-libs/mesa-21.1[X(+),egl(+),gbm(+)]
-	>=x11-libs/libdrm-2.4.89
+	>=x11-libs/libdrm-2.4.109
 	>=x11-libs/libXau-1.0.4
 	x11-libs/libxcvt
 	>=x11-libs/libXdmcp-1.0.2
@@ -45,7 +45,7 @@ COMMON_DEPEND="
 "
 DEPEND="
 	${COMMON_DEPEND}
-	x11-base/xorg-proto
+	>=x11-base/xorg-proto-2022.2
 	>=x11-libs/xtrans-1.3.5
 "
 RDEPEND="
@@ -85,6 +85,7 @@ src_configure() {
 		-Dxvfb=true
 		-Dxv=true
 		-Dxwayland-path="${EPREFIX}"/usr/bin
+		-Dlibdecor=false
 		-Ddocs=false
 		-Ddevel-docs=false
 		-Ddocs-pdf=false