x11-libs/libva-intel-driver: bump to 1.7.0

Package-Manager: portage-2.2.28
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/x11-libs/libva-intel-driver/libva-intel-driver-1.7.0.ebuild b/x11-libs/libva-intel-driver/libva-intel-driver-1.7.0.ebuild
new file mode 100644
index 000000000000..fea13863510d
--- /dev/null
+++ b/x11-libs/libva-intel-driver/libva-intel-driver-1.7.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+SCM=""
+if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
+	SCM=git-2
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="git://anongit.freedesktop.org/git/vaapi/intel-driver"
+fi
+
+AUTOTOOLS_AUTORECONF="yes"
+inherit autotools-multilib ${SCM}
+
+DESCRIPTION="HW video decode support for Intel integrated graphics"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/vaapi"
+if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
+	SRC_URI=""
+	S="${WORKDIR}/${PN}"
+else
+	SRC_URI="http://www.freedesktop.org/software/vaapi/releases/libva-intel-driver/${P}.tar.bz2"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+if [ "${PV%9999}" = "${PV}" ] ; then
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+else
+	KEYWORDS=""
+fi
+IUSE="+drm wayland X"
+
+RDEPEND=">=x11-libs/libva-1.6[X?,wayland?,drm?,${MULTILIB_USEDEP}]
+	!<x11-libs/libva-1.0.15[video_cards_intel]
+	>=x11-libs/libdrm-2.4.46[video_cards_intel,${MULTILIB_USEDEP}]
+	wayland? ( >=media-libs/mesa-9.1.6[egl,${MULTILIB_USEDEP}] >=dev-libs/wayland-1.0.6[${MULTILIB_USEDEP}] )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS NEWS README )
+
+src_prepare() {
+	sed -e 's/intel-gen4asm/\0diSaBlEd/g' -i configure.ac || die
+	autotools-multilib_src_prepare
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable drm)
+		$(use_enable wayland)
+		$(use_enable X x11)
+	)
+	autotools-utils_src_configure
+}