x11-libs/vte: Version bump

Package-Manager: portage-2.2.23

1 files changed, 70 insertions, 0 deletions

diff --git a/x11-libs/vte/vte-0.36.5.ebuild b/x11-libs/vte/vte-0.36.5.ebuild
new file mode 100644
index 000000000000..f240c9c588b0
--- /dev/null
+++ b/x11-libs/vte/vte-0.36.5.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit eutils gnome2
+
+DESCRIPTION="Library providing a virtual terminal emulator widget"
+HOMEPAGE="https://wiki.gnome.org/action/show/Apps/Terminal/VTE"
+
+LICENSE="LGPL-2+"
+SLOT="2.90"
+IUSE="debug glade +introspection"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~x64-solaris ~x86-solaris"
+
+PDEPEND=">=x11-libs/gnome-pty-helper-${PV}"
+RDEPEND="
+	>=dev-libs/glib-2.31.13:2
+	>=x11-libs/gtk+-3.1.9:3[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses:0=
+	x11-libs/libX11
+	x11-libs/libXft
+
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.13
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=663779
+	epatch "${FILESDIR}/${PN}-0.30.1-alt-meta.patch"
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+
+	if [[ ${CHOST} == *-interix* ]]; then
+		myconf="${myconf} --disable-Bsymbolic"
+
+		# interix stropts.h is empty...
+		export ac_cv_header_stropts_h=no
+	fi
+
+	# Python bindings are via gobject-introspection
+	# Ex: from gi.repository import Vte
+	# Do not disable gnome-pty-helper, bug #401389
+	gnome2_src_configure \
+		--disable-deprecation \
+		--disable-static \
+		$(use_enable debug) \
+		$(use_enable glade glade-catalogue) \
+		$(use_enable introspection) \
+		${myconf}
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	gnome2_src_install
+	rm -v "${ED}usr/libexec/gnome-pty-helper" || die
+}