x11-misc/sddm: Version bump

Package-Manager: portage-2.2.24

2 files changed, 66 insertions, 0 deletions

diff --git a/x11-misc/sddm/Manifest b/x11-misc/sddm/Manifest
index 7fa0ac18140b..957cdec861de 100644
--- a/x11-misc/sddm/Manifest
+++ b/x11-misc/sddm/Manifest
@@ -1,2 +1,3 @@
 DIST sddm-0.11.0.tar.gz 4735807 SHA256 80d53f075c275f744bd547523d6d640baccfacb4e463a71ec0facb8231b832ce SHA512 9dd2b80788e3cfdb353e64f709db451e04828991976b8b0f74c0e97dbf467fa2744702c73e5e50137eec10dac92df7dacd83fb458f75dd595556fc95fb1759f7 WHIRLPOOL 079c5093374710c2a3247a3e27dd26f3d10962c7cb8f260b80a4ba17a72e63676012d4b8e50f8f4bffc43124efdf05c7e14aefe86253b391345c7fa98a2d4c2f
 DIST sddm-0.12.0.tar.xz 3866620 SHA256 7d7504bf8a717a9131a2f32be852d7631365d21a468ca2649c8245f24ff29ae0 SHA512 d1d9f60634cb2a71096d92321a7a8b33efb8879a766979ca7c1d31ac5f1dbde8253384070338eef80f777db1cd78eef540e9111151f7f9e7d8e648d557e58047 WHIRLPOOL 58d21ead822b85bf3f0f6375cfadee6225dd9bf696e786fe68f283def43b4107d11e14b357d60b0278266270f9ddcb6a9b86285bc3b1a19644583f6ebebc4990
+DIST sddm-0.13.0.tar.xz 3869452 SHA256 dd868caaccf7783ead799f3b79e442d5adcb46251b78c8dbf3e9da0016dd347d SHA512 292a584945e74ea987088f975d5973b45a5b4fc07fa90b487fb9ece2de7ecca352344354474dfa8d103c8242367c19ad926e62a553e5b567d8d88a3f2c73c171 WHIRLPOOL e3961ecd5e22e8d565c16d86b6043ba7f3d6c1c296047d196577ab25af4e50216d67d53e9690b4df262c5ae4486bf36f88d345110a54bada9d75c4ff0dfc5ff3
diff --git a/x11-misc/sddm/sddm-0.13.0.ebuild b/x11-misc/sddm/sddm-0.13.0.ebuild
new file mode 100644
index 000000000000..71969d757a5e
--- /dev/null
+++ b/x11-misc/sddm/sddm-0.13.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils user
+
+DESCRIPTION="Simple Desktop Display Manager"
+HOMEPAGE="https://github.com/sddm/sddm"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.xz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="GPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0 public-domain"
+SLOT="0"
+IUSE="consolekit +pam systemd"
+
+RDEPEND="dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtnetwork:5
+	dev-qt/qttest:5
+	>=x11-base/xorg-server-1.15.1
+	x11-libs/libxcb[xkb(-)]
+	consolekit? ( >=sys-auth/consolekit-0.9.4 )
+	pam? ( sys-libs/pam )
+	systemd? ( sys-apps/systemd:= )
+	!systemd? ( || ( sys-power/upower sys-power/upower-pm-utils ) )"
+
+DEPEND="${RDEPEND}
+	dev-python/docutils
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary  && $(tc-getCC) == *gcc* ]]; then
+		if [[ $(gcc-major-version) -lt 4 || $(gcc-major-version) == 4 && $(gcc-minor-version) -lt 7 ]] ; then
+			die 'The active compiler needs to be gcc 4.7 (or newer)'
+		fi
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# fix for flags handling and bug 563108
+	epatch "${FILESDIR}/${PN}-0.12.0-respect-user-flags.patch"
+	use consolekit && epatch "${FILESDIR}/${PN}-0.11.0-consolekit.patch"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_no pam PAM)
+		$(cmake-utils_use_no systemd SYSTEMD)
+		-DBUILD_MAN_PAGES=ON
+		-DDBUS_CONFIG_FILENAME="org.freedesktop.sddm.conf"
+		)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN} video
+}