proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 68 insertions, 0 deletions

diff --git a/x11-plugins/pidgin-sipe/pidgin-sipe-1.18.0-r1.ebuild b/x11-plugins/pidgin-sipe/pidgin-sipe-1.18.0-r1.ebuild
new file mode 100644
index 000000000000..896b042ed24d
--- /dev/null
+++ b/x11-plugins/pidgin-sipe/pidgin-sipe-1.18.0-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools eutils
+
+DESCRIPTION="Pidgin Plug-in SIPE (Sip Exchange Protocol)"
+HOMEPAGE="http://sipe.sourceforge.net/"
+SRC_URI="mirror://sourceforge/sipe/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+IUSE="debug kerberos ocs2005-message-hack openssl telepathy voice"
+
+RDEPEND=">=dev-libs/gmime-2.4.16
+	dev-libs/libxml2
+	openssl? ( dev-libs/openssl )
+	!openssl? ( dev-libs/nss )
+	kerberos? ( virtual/krb5 )
+	voice? (
+		>=dev-libs/glib-2.28.0
+		>=net-libs/libnice-0.1.0
+		media-libs/gstreamer:0.10
+		>=net-im/pidgin-2.8.0
+	)
+	!voice? (
+		>=dev-libs/glib-2.12.0:2
+		net-im/pidgin
+	)
+	telepathy? (
+		>=sys-apps/dbus-1.1.0
+		>=dev-libs/dbus-glib-0.61
+		>=dev-libs/glib-2.28:2
+		>=net-libs/telepathy-glib-0.18.0
+	)
+"
+
+DEPEND="dev-util/intltool
+	virtual/pkgconfig
+	${RDEPEND}
+"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-1.13.2-fix-sandbox-r1.patch"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-purple \
+		--disable-quality-check \
+		$(use_enable telepathy) \
+		$(use_enable debug) \
+		$(use_enable ocs2005-message-hack) \
+		$(use_with kerberos krb5) \
+		$(use_with voice vv) \
+		$(use_enable !openssl nss) \
+		$(use_enable openssl)
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+	dodoc AUTHORS ChangeLog NEWS TODO README
+}