1 files changed, 0 insertions, 52 deletions
diff --git a/dev-cpp/glibmm/glibmm-2.70.0.ebuild b/dev-cpp/glibmm/glibmm-2.70.0.ebuild
deleted file mode 100644
index fa089ef8ecd2..000000000000
--- a/dev-cpp/glibmm/glibmm-2.70.0.ebuild
+++ /dev/null
@@ -1,52 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-PYTHON_COMPAT=( python3_{8..10} )
-inherit gnome.org meson-multilib python-any-r1
-
-DESCRIPTION="C++ interface for glib2"
-HOMEPAGE="https://www.gtkmm.org"
-
-LICENSE="LGPL-2.1+"
-SLOT="2.68"
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x86-solaris"
-IUSE="doc debug test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-libs/glib-2.69.1:2[${MULTILIB_USEDEP}]
-	dev-libs/libsigc++:3[doc?,${MULTILIB_USEDEP}]
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	${PYTHON_DEPS}
-	virtual/pkgconfig
-	doc? (
-		app-doc/doxygen[dot]
-		dev-lang/perl
-		dev-libs/libxslt
-	)
-"
-
-src_prepare() {
-	default
-
-	# giomm_tls_client requires FEATURES=-network-sandbox and glib-networking rdep
-	sed -i -e '/giomm_tls_client/d' tests/meson.build || die
-
-	if ! use test; then
-		sed -i -e "/^subdir('tests')/d" meson.build || die
-	fi
-}
-
-multilib_src_configure() {
-	local emesonargs=(
-		-Dwarnings=min
-		-Dbuild-deprecated-api=true
-		$(meson_native_use_bool doc build-documentation)
-		$(meson_use debug debug-refcounting)
-		-Dbuild-examples=false
-	)
-	meson_src_configure
-}