1 files changed, 56 insertions, 0 deletions
diff --git a/net-misc/ocsync/ocsync-0.91.4.ebuild b/net-misc/ocsync/ocsync-0.91.4.ebuild
new file mode 100644
index 000000000000..e6410a698f63
--- /dev/null
+++ b/net-misc/ocsync/ocsync-0.91.4.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="ownCloud fork of csync file synchronizer"
+HOMEPAGE="http://owncloud.org/"
+SRC_URI="http://download.owncloud.com/desktop/stable/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +iconv samba +sftp test"
+
+# Tests only work with iconv
+REQUIRED_USE="test? ( iconv )"
+
+RDEPEND=">=dev-db/sqlite-3.4:3
+	net-libs/neon[ssl]
+	iconv? ( virtual/libiconv )
+	samba? ( >=net-fs/samba-3.5 )
+	sftp? ( >=net-libs/libssh-0.5 )
+	!net-misc/csync
+	!>=net-misc/owncloud-client-1.5.1"
+DEPEND="${DEPEND}
+	doc? (
+		app-doc/doxygen
+		app-text/asciidoc
+	)
+	test? ( dev-util/cmocka )"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# proper docdir
+	sed -e "s:/doc/${PN}:/doc/${PF}:" \
+		-i doc/CMakeLists.txt || die
+	# Fix compilation with USE=-iconv, #500860
+	sed -e "s/_TCHAR/mbchar_t/" \
+		-i src/std/c_string.c || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		$(cmake-utils_use_with iconv ICONV)
+		$(cmake-utils_use test UNIT_TESTING)
+		$(cmake-utils_use_find_package doc Doxygen)
+		$(cmake-utils_use_find_package samba Libsmbclient)
+		$(cmake-utils_use_find_package sftp LibSSH)
+	)
+	cmake-utils_src_configure
+}