1 files changed, 48 insertions, 0 deletions
diff --git a/net-print/cups-pdf/cups-pdf-3.0.0.ebuild b/net-print/cups-pdf/cups-pdf-3.0.0.ebuild
new file mode 100644
index 000000000000..7bed03e6b62e
--- /dev/null
+++ b/net-print/cups-pdf/cups-pdf-3.0.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Provides a virtual printer for CUPS to produce PDF files"
+HOMEPAGE="http://www.cups-pdf.de/"
+SRC_URI="http://www.cups-pdf.de/src/${PN}_${PV/_}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="+ppds"
+
+RDEPEND="
+	net-print/cups
+	app-text/ghostscript-gpl
+"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${PN}-${PV/_}
+
+src_compile() {
+	pushd src >/dev/null
+	$(tc-getCC) ${LDFLAGS} ${CFLAGS} ${PN}.c -o ${PN} -lcups || die
+	popd >/dev/null
+}
+
+src_install() {
+	exeinto /usr/libexec/cups/backend
+	exeopts -m0700
+	doexe src/cups-pdf
+
+	insinto /etc/cups
+	doins extra/cups-pdf.conf
+
+	insinto /usr/share/cups/model
+	if use ppds; then
+		doins extra/CUPS-PDF_opt.ppd
+	else
+		doins extra/CUPS-PDF_noopt.ppd
+	fi
+
+	dodoc ChangeLog README
+}