3 files changed, 73 insertions, 0 deletions
diff --git a/sys-block/ndctl/Manifest b/sys-block/ndctl/Manifest
new file mode 100644
index 000000000000..d1e4db609220
--- /dev/null
+++ b/sys-block/ndctl/Manifest
@@ -0,0 +1 @@
+DIST ndctl-71.1.tar.gz 330512 BLAKE2B 582f29fb649f33a48b5412bfefc15de2b1f765b27251d1b8a472d8c7705d671acbd6bf646f737baf8556d8fda39db68242f44e11225d7305e95f5d2ec5931f31 SHA512 92fb06ca64455775ce0b89ba0846f70235e02fe3502e2a8a55a858f76f87cb90ae98f5bf01620e5884f667ea78ee2bee2cd9e7a85ffa8f8d9c456e9282ca9ebc
diff --git a/sys-block/ndctl/metadata.xml b/sys-block/ndctl/metadata.xml
new file mode 100644
index 000000000000..cee379b15409
--- /dev/null
+++ b/sys-block/ndctl/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>chutzpah@gentoo.org</email>
+		<name>Patrick McLean</name>
+	</maintainer>
+</pkgmetadata>
diff --git a/sys-block/ndctl/ndctl-71.1.ebuild b/sys-block/ndctl/ndctl-71.1.ebuild
new file mode 100644
index 000000000000..8791d7f43707
--- /dev/null
+++ b/sys-block/ndctl/ndctl-71.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools bash-completion-r1
+
+DESCRIPTION="Helper tools and libraries for managing non-volatile memory on Linux"
+HOMEPAGE="https://github.com/pmem/ndctl"
+SRC_URI="https://github.com/pmem/ndctl/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1 MIT CC0-1.0"
+SLOT="0/6"
+KEYWORDS="~amd64 ~x86"
+IUSE="bash-completion systemd test"
+
+DEPEND="
+	sys-apps/kmod:=
+	virtual/libudev:=
+	sys-apps/util-linux:=
+	dev-libs/json-c:=
+	systemd? ( sys-apps/systemd:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	app-text/asciidoc
+	app-text/xmlto
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+# tests require root access
+RESTRICT+=" test"
+
+DOCS=(
+	README.md
+	CONTRIBUTING.md
+)
+
+src_prepare() {
+	default
+	printf 'm4_define([GIT_VERSION], [%s])' "${PV}" > version.m4 || die
+	sed -e '/git-version-gen/ d' -i Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with bash-completion bash) \
+		$(use_with systemd) \
+		--disable-asciidoctor
+}
+
+src_test() {
+	emake check
+}
+
+src_install() {
+	default
+
+	use bash-completion && bashcomp_alias ndctl daxctl
+}