1 files changed, 66 insertions, 0 deletions
diff --git a/www-apps/prowlarr/prowlarr-1.10.2.4064.ebuild b/www-apps/prowlarr/prowlarr-1.10.2.4064.ebuild
new file mode 100644
index 000000000000..40ad30af1b3a
--- /dev/null
+++ b/www-apps/prowlarr/prowlarr-1.10.2.4064.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+SRC_URI="
+	amd64? (
+		elibc_glibc? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-core-x64.tar.gz )
+		elibc_musl? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-musl-core-x64.tar.gz )
+	)
+	arm? (
+		elibc_glibc? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-core-arm.tar.gz )
+		elibc_musl? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-musl-core-arm.tar.gz )
+	)
+	arm64? (
+		elibc_glibc? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-core-arm64.tar.gz )
+		elibc_musl? ( https://github.com/Prowlarr/Prowlarr/releases/download/v${PV}/Prowlarr.develop.${PV}.linux-musl-core-arm64.tar.gz )
+	)
+"
+
+DESCRIPTION="An indexer manager/proxy to integrate with your various PVR apps"
+HOMEPAGE="https://wiki.servarr.com/prowlarr"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm ~arm64"
+RESTRICT="bindist strip test"
+
+RDEPEND="
+	acct-group/prowlarr
+	acct-user/prowlarr
+	dev-libs/icu
+	dev-util/lttng-ust:0
+	dev-db/sqlite
+	sys-libs/glibc
+"
+
+QA_PREBUILT="*"
+
+S="${WORKDIR}/Prowlarr"
+
+src_prepare() {
+	default
+
+	# https://github.com/dotnet/runtime/issues/57784
+	rm libcoreclrtraceptprovider.so Prowlarr.Update/libcoreclrtraceptprovider.so || die
+}
+
+src_install() {
+	newinitd "${FILESDIR}/${PN}.init" ${PN}
+
+	keepdir /var/lib/${PN}
+	fowners -R ${PN}:${PN} /var/lib/${PN}
+
+	insinto /etc/logrotate.d
+	insopts -m0644 -o root -g root
+	newins "${FILESDIR}/${PN}.logrotate" ${PN}
+
+	dodir  "/opt/${PN}"
+	cp -R "${S}/." "${D}/opt/prowlarr" || die "Install failed!"
+
+	systemd_dounit "${FILESDIR}/prowlarr.service"
+	systemd_newunit "${FILESDIR}/prowlarr.service" "${PN}@.service"
+}