1 files changed, 49 insertions, 0 deletions
diff --git a/x11-plugins/purple-hangouts/purple-hangouts-0_p20181202.ebuild b/x11-plugins/purple-hangouts/purple-hangouts-0_p20181202.ebuild
new file mode 100644
index 000000000000..4be4edc68753
--- /dev/null
+++ b/x11-plugins/purple-hangouts/purple-hangouts-0_p20181202.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Hangouts Plugin for libpurple"
+HOMEPAGE="https://bitbucket.org/EionRobb/purple-hangouts"
+
+COMMIT_ID="cccf2f62d439"
+SRC_URI="https://bitbucket.org/EionRobb/purple-hangouts/get/${COMMIT_ID}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+S="${WORKDIR}/EionRobb-${PN}-${COMMIT_ID}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/protobuf-c:=
+	net-im/pidgin
+	sys-libs/zlib"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# Does not respect CFLAGS
+	sed -i Makefile -e 's/-g -ggdb//g' || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)"
+}
+
+src_install() {
+	emake \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		DESTDIR="${ED}" \
+		install
+
+	einstalldocs
+}