blob: 71aa7366350bcbff8003466a6c7e20ad2bfaaf73 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools readme.gentoo-r1
DESCRIPTION="AIDE (Advanced Intrusion Detection Environment) is a file integrity checker"
HOMEPAGE="https://aide.github.io/ https://github.com/aide/aide"
SRC_URI="https://github.com/aide/aide/releases/download/v${PV}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~arm64 x86"
IUSE="acl audit curl e2fs mhash selinux xattr"
DEPEND="dev-libs/libpcre
sys-libs/zlib
acl? ( virtual/acl )
audit? ( sys-process/audit )
curl? ( net-misc/curl )
e2fs? ( sys-fs/e2fsprogs )
!mhash? (
dev-libs/libgcrypt:0=
dev-libs/libgpg-error
)
mhash? ( app-crypt/mhash )
selinux? ( sys-libs/libselinux )
xattr? ( sys-apps/attr )"
RDEPEND="${DEPEND}
selinux? ( sec-policy/selinux-aide )"
BDEPEND="app-alternatives/yacc
app-alternatives/lex
virtual/pkgconfig"
DISABLE_AUTOFORMATTING=1
DOC_CONTENTS="
Example configuration file was installed at '${EPREFIX}/etc/aide/aide.conf'.
Please edit it to meet your needs. Refer to aide.conf(5) manual page
for more information.
A helper script, aideinit, was installed and can be used to make AIDE
management easier. Please run 'aideinit --help' for more information."
PATCHES=(
"${FILESDIR}"/${PN}-0.16-fix-acl-configure-option.patch
"${FILESDIR}"/${PN}-0.17.4-configure.patch
)
src_prepare() {
default
sed -i -e 's| -Werror||g' configure.ac || die
# Only needed for snapshots.
if [[ ${PV} == *_p* ]] ; then
echo "m4_define([AIDE_VERSION], [${PV}])" > version.m4 || die
fi
# Can be dropped once Bashism patch is gone
eautoreconf
}
src_configure() {
local myeconfargs=(
--sysconfdir="${EPREFIX}"/etc/${PN}
# Needed even in EAPI=8, >=portage-3.0.40 skips it here (bug #887177)
--disable-static
# Disable broken l10n support: https://sourceforge.net/p/aide/bugs/98/
# This doesn't affect anything because there are no localizations yet.
--without-locale
--without-prelink
--with-zlib
$(use_with curl)
$(use_with acl posix-acl)
$(use_with selinux)
$(use_with xattr)
$(use_with e2fs e2fsattrs)
$(use_with mhash mhash)
$(use_with !mhash gcrypt)
$(use_with audit)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
readme.gentoo_create_doc
insinto /etc/${PN}
insopts -m0600
newins "${FILESDIR}"/aide.conf-r2 aide.conf
dosbin "${FILESDIR}"/aideinit
dodoc -r contrib/ "${FILESDIR}"/aide.cron-r2
keepdir /var/{lib,log}/${PN}
}
pkg_postinst() {
readme.gentoo_print_elog
}
|
GitWeb