blob: 49d80f350b51320776fa7edd5ee6e27efcaae5f2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="7"
# Note: if bumping pax-utils because of syscall changes in glibc, please
# revbump glibc and update the dependency in its ebuild for the affected
# versions.
PYTHON_COMPAT=( python3_{8,9,10} )
inherit python-single-r1 toolchain-funcs
DESCRIPTION="ELF utils that can check files for security relevant properties"
HOMEPAGE="https://wiki.gentoo.org/index.php?title=Project:Hardened/PaX_Utilities"
SRC_URI="mirror://gentoo/${P}.tar.xz
https://dev.gentoo.org/~xen0n/distfiles/${P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="caps debug python seccomp"
RDEPEND="caps? ( >=sys-libs/libcap-2.24 )
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/pyelftools[${PYTHON_USEDEP}]
')
)
"
DEPEND="${RDEPEND}"
BDEPEND="
caps? ( virtual/pkgconfig )
"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
_emake() {
emake \
USE_CAP=$(usex caps) \
USE_DEBUG=$(usex debug) \
USE_PYTHON=$(usex python) \
USE_SECCOMP=$(usex seccomp) \
"$@"
}
pkg_setup() {
if use python; then
python-single-r1_pkg_setup
fi
}
src_configure() {
# Avoid slow configure+gnulib+make if on an up-to-date Linux system
if use prefix || ! use kernel_linux; then
econf $(use_with caps) $(use_with debug) $(use_with python) $(use_with seccomp)
else
tc-export CC PKG_CONFIG
fi
}
src_compile() {
_emake
}
src_test() {
_emake check
}
src_install() {
_emake DESTDIR="${D}" PKGDOCDIR='$(DOCDIR)'/${PF} install
use python && python_fix_shebang "${ED}"/usr/bin/lddtree
}
|
GitWeb
