blob: d27827cf8c04c6588a7ecf239a53fc668db10713 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
GNOME2_EAUTORECONF="yes"
GNOME2_LA_PUNT="yes"
inherit gnome2
DESCRIPTION="Fully featured yet light and fast cross platform word processor"
HOMEPAGE="http://www.abisource.com/"
SRC_URI="http://www.abisource.com/downloads/${PN}/${PV}/source/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~alpha amd64 ~arm ~mips ~x86 ~amd64-linux ~x86-linux"
IUSE="calendar collab cups debug eds +goffice grammar +introspection latex map math ots +plugins readline redland spell wordperfect wmf thesaurus"
# You need 'plugins' enabled if want to enable the extra plugins
REQUIRED_USE="!plugins? ( !collab !grammar !latex !math !ots !readline !thesaurus !wordperfect !wmf )"
RDEPEND="
>=app-text/wv-1.2
>=dev-libs/fribidi-0.10.4
>=dev-libs/glib-2.16:2
>=dev-libs/libgcrypt-1.4.5:0=
dev-libs/libxslt
>=gnome-base/librsvg-2.16:2
>=gnome-extra/libgsf-1.14.18:=
>=media-libs/libpng-1.2:0=
virtual/jpeg:0
>=x11-libs/cairo-1.10[X]
>=x11-libs/gtk+-3.0.8:3[cups?]
calendar? ( >=dev-libs/libical-0.46:= )
eds? ( >=gnome-extra/evolution-data-server-3.6.0:= )
goffice? ( >=x11-libs/goffice-0.10.2:0.10 )
introspection? ( >=dev-libs/gobject-introspection-1.0.0:= )
map? ( >=media-libs/libchamplain-0.12:0.12 )
plugins? (
collab? (
>=dev-libs/libxml2-2.4:2
>=net-libs/loudmouth-1
net-libs/libsoup:2.4
net-libs/gnutls:= )
grammar? ( >=dev-libs/link-grammar-4.2.1 )
math? ( >=x11-libs/gtkmathview-0.7.5 )
ots? ( >=app-text/ots-0.5-r1 )
readline? ( sys-libs/readline:0= )
thesaurus? ( >=app-text/aiksaurus-1.2[gtk] )
wordperfect? (
app-text/libwpd:0.10
app-text/libwpg:0.3 )
wmf? ( >=media-libs/libwmf-0.2.8 )
)
redland? (
>=dev-libs/redland-1.0.10
>=dev-libs/rasqal-0.9.17 )
spell? ( >=app-text/enchant-1.2 )
!<app-office/abiword-plugins-2.8
"
DEPEND="${RDEPEND}
dev-lang/perl
>=dev-libs/boost-1.40.0
virtual/pkgconfig
collab? ( dev-cpp/asio )
"
PATCHES=(
# http://bugzilla.abisource.com/show_bug.cgi?id=13842
"${FILESDIR}"/${PN}-2.8.3-desktop.patch
# http://bugzilla.abisource.com/show_bug.cgi?id=13843
"${FILESDIR}"/${PN}-2.6.0-boolean.patch
# http://bugzilla.abisource.com/show_bug.cgi?id=13844
"${FILESDIR}"/${PN}-3.0.0-librevenge.patch
# http://bugzilla.abisource.com/show_bug.cgi?id=13845
"${FILESDIR}"/${PN}-3.0.0-link-grammar-5-second.patch
# http://bugzilla.abisource.com/show_bug.cgi?id=13846
"${FILESDIR}"/${PN}-3.0.0-libwp.patch
"${FILESDIR}"/${PN}-3.0.1-libwps-0.4.patch
"${FILESDIR}"/${PN}-3.0.1-fixwps.patch
# http://bugzilla.abisource.com/show_bug.cgi?id=13847
"${FILESDIR}"/${PN}-3.0.2-fix-installing-readme.patch
# http://bugzilla.abisource.com/show_bug.cgi?id=13841
"${FILESDIR}"/${PN}-3.0.2-fix-nullptr-c++98.patch
# http://bugzilla.abisource.com/show_bug.cgi?id=13815
"${FILESDIR}"/${PN}-3.0.2-fix-black-drawing-regression.patch
)
src_configure() {
local plugins=()
if use plugins; then
# Plugins depending on libgsf
plugins=(t602 docbook clarisworks wml kword hancom openwriter pdf
loadbindings mswrite garble pdb applix opendocument sdw xslfo)
# Plugins depending on librsvg
plugins+=(svg)
# Plugins not depending on anything
plugins+=(gimp bmp freetranslation iscii s5 babelfish opml eml wikipedia
gdict passepartout google presentation urldict hrtext mif openxml)
# inter7eps: eps.h
# libtidy: gsf + tidy.h
# paint: windows only ?
use collab && plugins+=(collab)
use goffice && plugins+=(goffice)
use latex && plugins+=(latex)
use math && plugins+=(mathview)
use ots && plugins+=(ots)
# psion: >=psiconv-0.9.4
use readline && plugins+=(command)
use thesaurus && plugins+=(aiksaurus)
use wmf && plugins+=(wmf)
# wordperfect: >=wpd-0.9 >=wpg-0.2
use wordperfect && plugins+=(wpg)
fi
gnome2_src_configure \
--enable-plugins="${plugins[*]}" \
--disable-static \
--disable-default-plugins \
--disable-builtin-plugins \
--disable-collab-backend-telepathy \
--enable-clipart \
--enable-statusbar \
--enable-templates \
--with-gio \
--without-gnomevfs \
--without-gtk2 \
$(use_enable debug) \
$(use_with goffice goffice) \
$(use_with calendar libical) \
$(use_enable cups print) \
$(use_enable collab collab-backend-xmpp) \
$(use_enable collab collab-backend-tcp) \
$(use_enable collab collab-backend-service) \
$(use_with eds evolution-data-server) \
$(use_enable introspection) \
$(use_with map champlain) \
$(use_with redland) \
$(use_enable spell)
}
|
GitWeb