app-text/cherrytree/cherrytree-0.37.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

PYTHON_COMPAT=( python2_7 )
DISTUTILS_SINGLE_IMPL=true

inherit fdo-mime distutils-r1

DESCRIPTION='A hierarchical note taking application'
HOMEPAGE='http://www.giuspen.com/cherrytree'
LICENSE='GPL-3'

SLOT='0'
SRC_URI="https://github.com/giuspen/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

KEYWORDS='~amd64 ~x86'
IUSE='nls'

RDEPEND="
	x11-libs/libX11
	dev-python/dbus-python[${PYTHON_USEDEP}]
	dev-python/pyenchant[${PYTHON_USEDEP}]
	>=dev-python/pygtk-2.16:2[${PYTHON_USEDEP}]
	dev-python/pygtksourceview:2[${PYTHON_USEDEP}]
"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
"

PLOCALES='cs de es fr hy it ja lt nl pl pt_BR ru sl tr uk zh_CN'
inherit l10n

python_prepare_all() {
	if use nls ; then
		l10n_find_plocales_changes 'locale' '' '.po'

		rm_loc() {
			rm -v -f "locale/${1}.po" || return 1
		}
		l10n_for_each_disabled_locale_do rm_loc
	fi

	sed -i '\|update-desktop-database|d' 'setup.py' || die

	distutils-r1_python_prepare_all
}

python_configure_all() {
	use nls || mydistutilsargs+=( '--without-gettext' )
	distutils-r1_python_configure_all
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}