blob: 661cc49ff2a701c5cac64a6225feebd7183a8055 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{2_7,3_5,3_6} )
CMAKE_BUILD_TYPE="Release"
inherit python-any-r1 cmake-multilib flag-o-matic llvm toolchain-funcs
DESCRIPTION="OpenCL implementation for Intel GPUs"
HOMEPAGE="https://01.org/beignet https://gitlab.freedesktop.org/beignet/beignet"
LICENSE="LGPL-2.1+"
SLOT="0"
IUSE="ocl-icd ocl20"
if [[ "${PV}" == "9999" ]]; then
inherit git-r3
EGIT_REPO_URI="https://gitlab.freedesktop.org/beignet/beignet.git"
KEYWORDS=""
else
KEYWORDS="~amd64"
SRC_URI="https://01.org/sites/default/files/${P}-source.tar.gz"
S=${WORKDIR}/Beignet-${PV}-Source
fi
COMMON="app-eselect/eselect-opencl
media-libs/mesa[${MULTILIB_USEDEP}]
<sys-devel/clang-6.0.9999:=[${MULTILIB_USEDEP}]
>=x11-libs/libdrm-2.4.70[video_cards_intel,${MULTILIB_USEDEP}]
x11-libs/libXext[${MULTILIB_USEDEP}]
x11-libs/libXfixes[${MULTILIB_USEDEP}]
ocl-icd? ( dev-libs/ocl-icd )"
RDEPEND="${COMMON}"
DEPEND="${COMMON}
${PYTHON_DEPS}
virtual/pkgconfig"
LLVM_MAX_SLOT=6
PATCHES=(
"${FILESDIR}"/no-debian-multiarch.patch
"${FILESDIR}"/${PN}-1.3.2_disable-doNegAddOptimization.patch
"${FILESDIR}"/${PN}-1.3.2_cmake-llvm-config-multilib.patch
"${FILESDIR}"/${PN}-1.3.2_llvm6.patch
"${FILESDIR}"/${PN}-1.3.1-oclicd_no_upstream_icdfile.patch
"${FILESDIR}"/${PN}-1.2.0_no-hardcoded-cflags.patch
"${FILESDIR}"/llvm-terminfo.patch
)
DOCS=(
docs/.
)
pkg_pretend() {
if [[ ${MERGE_TYPE} != "binary" ]]; then
if tc-is-gcc; then
if [[ $(gcc-major-version) -eq 4 ]] && [[ $(gcc-minor-version) -lt 6 ]]; then
eerror "Compilation with gcc older than 4.6 is not supported"
die "Too old gcc found."
fi
fi
fi
}
pkg_setup() {
llvm_pkg_setup
python_setup
}
src_prepare() {
# See Bug #593968
append-flags -fPIC
cmake-utils_src_prepare
# We cannot run tests because they require permissions to access
# the hardware, and building them is very time-consuming.
cmake_comment_add_subdirectory utests
}
multilib_src_configure() {
VENDOR_DIR="/usr/$(get_libdir)/OpenCL/vendors/${PN}"
local mycmakeargs=(
-DCMAKE_INSTALL_PREFIX="${EPREFIX}${VENDOR_DIR}"
-DOCLICD_COMPAT=$(usex ocl-icd)
$(usex ocl20 "" "-DENABLE_OPENCL_20=OFF")
)
cmake-utils_src_configure
}
multilib_src_install() {
VENDOR_DIR="/usr/$(get_libdir)/OpenCL/vendors/${PN}"
cmake-utils_src_install
insinto /etc/OpenCL/vendors/
echo "${EPREFIX}${VENDOR_DIR}/lib/${PN}/libcl.so" > "${PN}-${ABI}.icd" || die "Failed to generate ICD file"
doins "${PN}-${ABI}.icd"
dosym "lib/${PN}/libcl.so" "${VENDOR_DIR}"/libOpenCL.so.1
dosym "lib/${PN}/libcl.so" "${VENDOR_DIR}"/libOpenCL.so
dosym "lib/${PN}/libcl.so" "${VENDOR_DIR}"/libcl.so.1
dosym "lib/${PN}/libcl.so" "${VENDOR_DIR}"/libcl.so
}
pkg_postinst() {
if use ocl-icd; then
"${ROOT}"/usr/bin/eselect opencl set --use-old ocl-icd
else
"${ROOT}"/usr/bin/eselect opencl set --use-old beignet
fi
}
|
GitWeb