blob: 89c22412183e4f8a0ef96c1e80f1e1029ed0f402 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools multilib multilib-minimal preserve-libs toolchain-funcs
DESCRIPTION="A library for manipulating integer points bounded by linear constraints"
HOMEPAGE="http://isl.gforge.inria.fr/ https://libisl.sourceforge.io/"
SRC_URI="http://isl.gforge.inria.fr/${P}.tar.xz https://libisl.sourceforge.io/${P}.tar.xz"
LICENSE="LGPL-2.1"
SLOT="0/23"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
IUSE="static-libs"
RDEPEND=">=dev-libs/gmp-5.1.3-r1:=[${MULTILIB_USEDEP}]"
DEPEND="${RDEPEND}"
BDEPEND="
app-arch/xz-utils
virtual/pkgconfig"
DOCS=( ChangeLog AUTHORS doc/manual.pdf )
PATCHES=(
"${FILESDIR}"/${PN}-0.24-gdb-autoload-dir.patch
"${FILESDIR}"/${PN}-0.24-nobash.patch
"${FILESDIR}"/${PN}-0.24-respect-flags.patch
)
src_prepare() {
default
eautoreconf
}
multilib_src_configure() {
local econf_opts=(
$(use_enable static-libs static)
# AX_PROG_CC_FOR_BUILD deficiency:
# https://wiki.gentoo.org/wiki/Project:Toolchain/use_native_symlinks
CC_FOR_BUILD="$(tc-getBUILD_CC)"
)
if ! tc-is-cross-compiler; then
# Incorrect CFLAGS handling as CFLAGS_FOR_BUILD
# even for native builds. As a result -O3 is being used
# regardless of user's CFLAGS.
econf_opts+=(
CFLAGS_FOR_BUILD="${CFLAGS}"
)
fi
ECONF_SOURCE="${S}" econf "${econf_opts[@]}"
}
multilib_src_install_all() {
einstalldocs
find "${ED}" -type f -name '*.la' -delete || die
}
pkg_preinst() {
preserve_old_lib \
/usr/$(get_libdir)/libisl$(get_libname 14) \
/usr/$(get_libdir)/libisl$(get_libname 15) \
/usr/$(get_libdir)/libisl$(get_libname 19) \
/usr/$(get_libdir)/libisl$(get_libname 21) \
/usr/$(get_libdir)/libisl$(get_libname 22)
}
pkg_postinst() {
preserve_old_lib_notify \
/usr/$(get_libdir)/libisl$(get_libname 14) \
/usr/$(get_libdir)/libisl$(get_libname 15) \
/usr/$(get_libdir)/libisl$(get_libname 19) \
/usr/$(get_libdir)/libisl$(get_libname 21) \
/usr/$(get_libdir)/libisl$(get_libname 22)
}
|
GitWeb