blob: fac59ec70b21a0bd39a276a401a29886c9a511ac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 2022-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=sip
PYPI_NO_NORMALIZE=1
PYPI_PN=${PN/-/_}
PYTHON_COMPAT=( python3_{9..11} )
inherit distutils-r1 flag-o-matic multiprocessing pypi qmake-utils
QT_PV="$(ver_cut 1-2):6"
DESCRIPTION="Python bindings for QtWebEngine"
HOMEPAGE="https://www.riverbankcomputing.com/software/pyqtwebengine/"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="debug quick +widgets"
RDEPEND="
>=dev-python/PyQt6-${PV}[gui,ssl,${PYTHON_USEDEP}]
>=dev-qt/qtbase-${QT_PV}
>=dev-qt/qtwebengine-${QT_PV}[widgets]
quick? ( dev-python/PyQt6[qml] )
widgets? ( dev-python/PyQt6[network,printsupport,webchannel,widgets] )"
DEPEND="${RDEPEND}"
BDEPEND="
>=dev-python/PyQt-builder-1.11[${PYTHON_USEDEP}]
>=dev-qt/qtbase-${QT_PV}
sys-devel/gcc"
src_prepare() {
default
# hack: qmake queries g++ directly for info (not building) and that doesn't
# work with clang, this is to make it at least respect CHOST (bug #726112)
mkdir "${T}"/cxx || die
ln -s "$(type -P ${CHOST}-g++ || type -P g++ || die)" "${T}"/cxx/g++ || die
PATH=${T}/cxx:${PATH}
}
python_configure_all() {
append-cxxflags -std=c++17 # for old gcc / clang that use <17 (bug #892331)
append-cxxflags ${CPPFLAGS} # respect CPPFLAGS
DISTUTILS_ARGS=(
--jobs=$(makeopts_jobs)
--qmake="$(type -P qmake6 || die)"
--qmake-setting="$(qt5_get_qmake_args)"
--verbose
--enable=QtWebEngineCore
$(usex quick --{enable,disable}=QtWebEngineQuick)
$(usex widgets --{enable,disable}=QtWebEngineWidgets)
$(usev debug '--debug --qml-debug --tracing')
)
}
|
GitWeb
