blob: 47acc9cdeb6dafacd6c8d1a94418bdf0bdf74bb3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
PYTHON_COMPAT=( python2_7 python3_{4,5} )
inherit distutils-r1
DESCRIPTION="Python to GNU Octave bridge"
HOMEPAGE="
https://pypi.python.org/pypi/oct2py
http://pythonhosted.org/oct2py/
https://github.com/blink1073/oct2py"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples test"
RDEPEND="
>=dev-python/numpy-1.7.1[${PYTHON_USEDEP}]
>=sci-libs/scipy-0.12[${PYTHON_USEDEP}]
sci-mathematics/octave"
DEPEND="${RDEPEND}
doc? (
dev-python/sphinx-bootstrap-theme[${PYTHON_USEDEP}]
dev-python/numpydoc[${PYTHON_USEDEP}]
)
test? (
dev-python/nose[${PYTHON_USEDEP}]
dev-python/ipython[${PYTHON_USEDEP}]
)"
python_prepare_all() {
# https://github.com/blink1073/oct2py/issues/77
sed \
-e 's:test_help:disabled:g' \
-i oct2py/tests/test_usage.py || die
distutils-r1_python_prepare_all
}
python_compile_all() {
if use doc; then
sphinx-build docs html || die
fi
}
python_test() {
unset DISPLAY
if [[ ${EPYTHON} == python2.7 ]]; then
local OPTIONS="--with-doctest"
fi
nosetests --exe -v oct2py ${OPTIONS} || die "Tests fail with ${EPYTHON}"
}
python_install_all() {
use doc && local HTML_DOCS=( html/. )
use examples && EXAMPLES=( example/. )
distutils-r1_python_install_all
}
|
GitWeb
