blob: d6d81c31e27c33804d71b2f38171af54775e137d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
PYPI_PN=${PN/-/.}
PYTHON_COMPAT=( python3_{9..12} pypy3 )
inherit distutils-r1 pypi
DESCRIPTION="Interfaces for Python"
HOMEPAGE="
https://github.com/zopefoundation/zope.interface/
https://pypi.org/project/zope.interface/
"
LICENSE="ZPL"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc64-solaris ~x64-solaris"
RDEPEND="
!dev-python/namespace-zope
"
BDEPEND="
test? (
dev-python/zope-event[${PYTHON_USEDEP}]
dev-python/zope-testing[${PYTHON_USEDEP}]
)
"
distutils_enable_tests unittest
src_prepare() {
# strip rdep specific to namespaces
sed -e "/'setuptools'/d" -i setup.py || die
distutils-r1_src_prepare
}
python_compile() {
distutils-r1_python_compile
find "${BUILD_DIR}" -name '*.pth' -delete || die
}
python_test() {
cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
distutils_write_namespace zope
eunittest
}
|
GitWeb
