blob: f20b5f1cb91365c2545669447c3a65b71a27e9ea (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
USE_RUBY="ruby25 ruby26"
# this is not null so that the dependencies will actually be filled
RUBY_FAKEGEM_TASK_TEST="test"
RUBY_FAKEGEM_RECIPE_DOC="none"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
RUBY_FAKEGEM_GEMSPEC="activerecord.gemspec"
RUBY_FAKEGEM_BINWRAP=""
inherit ruby-fakegem
DESCRIPTION="Implements the ActiveRecord pattern (Fowler, PoEAA) for ORM"
HOMEPAGE="https://github.com/rails/rails/"
SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
LICENSE="MIT"
SLOT="$(ver_cut 1-2)"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
IUSE="mysql postgres sqlite"
RUBY_S="rails-${PV}/${PN}"
ruby_add_rdepend "~dev-ruby/activesupport-${PV}
~dev-ruby/activemodel-${PV}
dev-ruby/arel:9.0
sqlite? ( >=dev-ruby/sqlite3-1.4 )
mysql? ( || ( dev-ruby/mysql2:0.5 >=dev-ruby/mysql2-0.4.4:0.4 ) )
postgres? ( || ( dev-ruby/pg:1 >=dev-ruby/pg-0.18.0:0 ) )"
ruby_add_bdepend "
test? (
dev-ruby/bundler
~dev-ruby/actionpack-${PV}
>=dev-ruby/sqlite3-1.3.6
dev-ruby/mocha
dev-ruby/minitest:5
)"
DEPEND+=" test? ( >=dev-db/sqlite-3.12.1 )"
all_ruby_prepare() {
# Remove items from the common Gemfile that we don't need for this
# test run. This also requires handling some gemspecs.
rm ../Gemfile.lock || die
sed -i -e "/\(uglifier\|system_timer\|sdoc\|w3c_validators\|pg\|jquery-rails\|execjs\|'mysql'\|journey\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|redcarpet\|minitest\|sprockets\|stackprof\)/ s:^:#:" \
-e '/:job/,/end/ s:^:#:' \
-e '/group :doc/,/^end/ s:^:#:' ../Gemfile || die
sed -i -e '/rack-ssl/d' -e 's/~> 3.4/>= 3.4/' ../railties/railties.gemspec || die
sed -e '/bcrypt/ s/3.0.0/3.0/' \
-i ../Gemfile || die
# Add back json in the Gemfile because we dropped some dependencies
# earlier that implicitly required it.
sed -i -e '$agem "json"' ../Gemfile || die
# Avoid test depending on mysql adapter which we don't support for
# this Rails version to simplify our dependencies.
rm test/cases/connection_specification/resolver_test.rb || die
# Avoid single tests using mysql or postgres dependencies.
rm test/cases/invalid_connection_test.rb || die
sed -e '/test_switching_connections_with_database_url/askip "postgres"' \
-i test/cases/connection_adapters/connection_handlers_multi_db_test.rb || die
# Avoid failing test that makes bad assumptions on database state.
sed -i -e '/test_do_not_call_callbacks_for_delete_all/,/^ end/ s:^:#:' \
test/cases/associations/has_many_associations_test.rb
# Avoid test failing to bind limit length in favor of security release
sed -i -e '/test_too_many_binds/askip "Fails on Gentoo"' test/cases/bind_parameter_test.rb || die
}
each_ruby_test() {
if use sqlite; then
${RUBY} -S rake test_sqlite3 || die "sqlite3 tests failed"
fi
}
|
GitWeb