blob: 811aa57890610f61539b737bce0a8b57d32d1765 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit mate
if [[ ${PV} != 9999 ]]; then
KEYWORDS="amd64 ~arm ~arm64 x86"
fi
DESCRIPTION="MATE session manager"
HOMEPAGE="https://mate-desktop.org/"
LICENSE="GPL-2+ GPL-3+ HPND LGPL-2+ LGPL-2.1+"
SLOT="0"
IUSE="debug elogind gnome-keyring ipv6 systemd +xtrans"
REQUIRED_USE="^^ ( elogind systemd )"
# x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
# create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
# xdg-user-dirs-update is run during login (see 10-user-dirs-update-gnome below).
COMMON_DEPEND="
>=dev-libs/dbus-glib-0.76
>=dev-libs/glib-2.50:2
dev-libs/libxslt
sys-apps/dbus
x11-libs/gdk-pixbuf:2
>=x11-libs/gtk+-3.22:3
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-libs/libXau
x11-libs/libXext
x11-libs/libXrender
x11-libs/libXtst
x11-libs/pango
systemd? ( sys-apps/systemd )
elogind? ( sys-auth/elogind )
xtrans? ( x11-libs/xtrans )"
RDEPEND="${COMMON_DEPEND}
virtual/libintl
x11-apps/xdpyinfo
x11-misc/xdg-user-dirs
x11-misc/xdg-user-dirs-gtk
gnome-keyring? ( gnome-base/gnome-keyring )
!<gnome-base/gdm-2.20.4"
DEPEND="${COMMON_DEPEND}
>=dev-lang/perl-5
dev-util/glib-utils
>=sys-devel/gettext-0.19.8:*
virtual/pkgconfig"
MATE_FORCE_AUTORECONF=true
src_configure() {
mate_src_configure \
$(use_with elogind) \
$(use_with systemd) \
$(use_with xtrans) \
$(use_enable debug) \
$(use_enable ipv6)
}
src_install() {
mate_src_install
exeinto /etc/X11/Sessions/
doexe "${FILESDIR}"/MATE
insinto /usr/share/mate/applications/
doins "${FILESDIR}"/defaults.list
exeinto /etc/X11/xinit/xinitrc.d/
newexe "${FILESDIR}"/15-xdg-data-mate-r2 15-xdg-data-mate
# This should be done in MATE too, see Gentoo bug #270852
newexe "${FILESDIR}"/10-user-dirs-update-mate-r2 10-user-dirs-update-mate
}
|
GitWeb