blob: bb7591ba329d7335f527f685f123b215e48bf50c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake
DESCRIPTION="OpenGL Mathematics"
HOMEPAGE="http://glm.g-truc.net/"
SRC_URI="https://github.com/g-truc/glm/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="|| ( HappyBunny MIT )"
SLOT="0"
KEYWORDS="amd64 ~arm arm64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="test cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_avx cpu_flags_x86_avx2"
RESTRICT="!test? ( test )"
RDEPEND=""
PATCHES=(
"${FILESDIR}"/${PN}-0.9.9.6-simd.patch
"${FILESDIR}"/${P}-clang.patch
)
src_configure() {
# Header-only library
if use test; then
local mycmakeargs=(
-DGLM_TEST_ENABLE=ON
-DGLM_TEST_ENABLE_SIMD_SSE2="$(usex cpu_flags_x86_sse2 ON OFF)"
-DGLM_TEST_ENABLE_SIMD_SSE3="$(usex cpu_flags_x86_sse3 ON OFF)"
-DGLM_TEST_ENABLE_SIMD_AVX="$(usex cpu_flags_x86_avx ON OFF)"
-DGLM_TEST_ENABLE_SIMD_AVX2="$(usex cpu_flags_x86_avx2 ON OFF)"
)
cmake_src_configure
fi
sed \
-e "s:@CMAKE_INSTALL_PREFIX@:${EPREFIX}/usr:" \
-e "s:@GLM_VERSION@:$(ver_cut 1-3):" \
"${FILESDIR}"/glm.pc.in \
> "${BUILD_DIR}/glm.pc" || die
}
src_compile() {
# Header-only library
if use test; then
cmake_src_compile
fi
}
src_install() {
doheader -r glm
insinto /usr/share/pkgconfig
doins "${BUILD_DIR}/glm.pc"
insinto /usr/share
doins -r cmake
dodoc readme.md manual.md
}
|
GitWeb
