blob: 29deec7e93d738575fba6af6a9f87e9ada98a3dd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit multilib-minimal toolchain-funcs
MY_PN=LibRaw
MY_PV="${PV/_b/-B}"
MY_P="${MY_PN}-${MY_PV}"
DESCRIPTION="LibRaw is a library for reading RAW files obtained from digital photo cameras"
HOMEPAGE="https://www.libraw.org/ https://github.com/LibRaw/LibRaw"
SRC_URI="https://www.libraw.org/data/${MY_P}.tar.gz
demosaic? (
https://www.libraw.org/data/LibRaw-demosaic-pack-GPL2-${MY_PV}.tar.gz
https://www.libraw.org/data/LibRaw-demosaic-pack-GPL3-${MY_PV}.tar.gz
)"
LICENSE="LGPL-2.1 CDDL demosaic? ( GPL-2 GPL-3 )"
SLOT="0/16" # subslot = libraw soname version
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="demosaic examples jpeg jpeg2k +lcms openmp"
RDEPEND="jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
jpeg2k? ( >=media-libs/jasper-1.900.1-r6:=[${MULTILIB_USEDEP}] )
lcms? ( >=media-libs/lcms-2.5:2[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
virtual/pkgconfig"
S="${WORKDIR}/${MY_P}"
DOCS=( Changelog.txt README )
PATCHES=(
"${FILESDIR}"/${PN}-0.18.4-glibc-2.27.patch
)
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
multilib_src_configure() {
local myeconfargs=(
--disable-static
$(use_enable demosaic demosaic-pack-gpl2)
$(use_enable demosaic demosaic-pack-gpl3)
$(use_enable examples)
$(use_enable jpeg)
$(use_enable jpeg2k jasper)
$(use_enable lcms)
$(use_enable openmp)
)
ECONF_SOURCE="${S}" \
econf "${myeconfargs[@]}"
}
multilib_src_install_all() {
einstalldocs
# package installs .pc files
find "${D}" -name '*.la' -delete || die
}
|
GitWeb
