blob: fc6e671684657341d7898a189b0022d5fbb302fb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
MY_P=${P/dvds/DVDS}
WX_GTK_VER=3.0
inherit wxwidgets
DESCRIPTION="A cross-platform free DVD authoring application"
HOMEPAGE="https://www.dvdstyler.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
S="${WORKDIR}/${MY_P}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug +udev"
DEPEND="
app-cdr/cdrtools
>=app-cdr/dvd+rw-tools-7.1
media-libs/libexif:=
>=media-libs/wxsvg-1.5.11:=
>=media-video/dvdauthor-0.7.1
>=media-video/ffmpeg-2.6:0=[encode]
>=media-video/xine-ui-0.99.7
virtual/jpeg:0
x11-libs/wxGTK:${WX_GTK_VER}=[gstreamer,X]
sys-apps/dbus
udev? ( >=virtual/libudev-215:= )"
RDEPEND="${DEPEND}
>=app-cdr/dvdisaster-0.72.4
media-video/mjpegtools"
BDEPEND="
app-arch/zip
app-text/xmlto
sys-devel/gettext
virtual/yacc
virtual/pkgconfig"
PATCHES=( "${FILESDIR}"/ffmpeg4.patch )
src_prepare() {
default
# disable obsolete GNOME 2.x libraries wrt #508854
sed -i -e '/PKG_CONFIG/s:libgnomeui-2.0:dIsAbLeAuToMaGiC&:' configure || die
# rmdir: failed to remove `tempfoobar': Directory not empty
sed -i -e '/rmdir "$$t"/d' docs/Makefile.in || die
# fix underlinking wrt #367863
sed -i -e 's:@LIBS@:& -ljpeg:' wxVillaLib/Makefile.in || die
# silence desktop-file-validate QA check
sed -i \
-e '/Icon/s:.png::' -e '/^Encoding/d' -e '/Categories/s:Application;::' \
data/dvdstyler.desktop || die
}
src_configure() {
setup-wxwidgets unicode
econf \
$(use_enable debug) \
--with-wx-config="${WX_CONFIG}"
}
src_install() {
default
rm "${ED}"/usr/share/doc/${PF}/{COPYING*,INSTALL*} || die
}
|
GitWeb
