blob: 04665c7bc53b79dcd5f21183778c7f493e6dd611 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9,10} )
inherit autotools python-single-r1 multilib-minimal
DESCRIPTION="A library with the aim to simplify DNS programming in C"
HOMEPAGE="https://www.nlnetlabs.nl/projects/ldns/"
SRC_URI="https://www.nlnetlabs.nl/downloads/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0/3"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="doc examples python static-libs"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RESTRICT="test" # missing test directory
BDEPEND="
python? ( dev-lang/swig )
doc? ( app-doc/doxygen )
"
DEPEND="
python? ( ${PYTHON_DEPS} )
>=dev-libs/openssl-1.1.1l-r1:0=[${MULTILIB_USEDEP},static-libs?]
examples? ( net-libs/libpcap )
"
RDEPEND="
${DEPEND}
!<net-dns/ldns-utils-1.8.0-r2
"
MULTILIB_CHOST_TOOLS=(
/usr/bin/ldns-config
)
PATCHES=(
"${FILESDIR}/ldns-1.8.1-pkgconfig.patch"
"${FILESDIR}/${P}-docs.patch"
"${FILESDIR}/${P}-configure-strict.patch"
)
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
default
# Drop after 1.8.3
eautoreconf
}
multilib_src_configure() {
ECONF_SOURCE="${S}" econf \
$(use_enable static-libs static) \
$(multilib_native_use_with python pyldns) \
$(multilib_native_use_with python pyldnsx) \
--with-ssl="${EPREFIX}"/usr \
$(multilib_native_with drill) \
$(multilib_native_use_with examples) \
--disable-rpath
}
multilib_src_compile() {
default
if multilib_is_native_abi && use doc ; then
emake doxygen
fi
}
multilib_src_install() {
default
if multilib_is_native_abi && use doc ; then
dodoc -r doc/html
fi
}
multilib_src_install_all() {
dodoc Changelog README*
find "${D}" -name '*.la' -delete || die
use python && python_optimize
insinto /usr/share/vim/vimfiles/ftdetect
doins libdns.vim
}
|
GitWeb