blob: be9bd1d1b4b8bca73e98decce1a7ced53f958c52 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools bash-completion-r1 eutils vcs-snapshot
DESCRIPTION="Mobile shell that supports roaming and intelligent local echo"
HOMEPAGE="https://mosh.org"
SRC_URI="https://mosh.org/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="alpha amd64 ~arm ~arm64 ia64 ~mips ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~x64-macos"
IUSE="+client examples libressl +mosh-hardening +server ufw +utempter"
REQUIRED_USE="
|| ( client server )
examples? ( client )"
RDEPEND="
dev-libs/protobuf:0=
sys-libs/ncurses:0=
virtual/ssh
client? (
dev-lang/perl
dev-perl/IO-Tty
)
libressl? (
dev-libs/libressl:0=
)
!libressl? (
dev-libs/openssl:0=
)
utempter? (
sys-libs/libutempter
)"
DEPEND="${RDEPEND}
virtual/pkgconfig"
# [0] - avoid sandbox-violation calling git describe in Makefile.
PATCHES=(
"${FILESDIR}"/${PN}-1.2.5-git-version.patch
)
src_prepare() {
MAKEOPTS+=" V=1"
default
eautoreconf
}
src_configure() {
econf \
--disable-completion \
$(use_enable client) \
$(use_enable server) \
$(use_enable examples) \
$(use_enable ufw) \
$(use_enable mosh-hardening hardening) \
$(use_with utempter)
}
src_install() {
default
for myprog in $(find src/examples -type f -perm /0111) ; do
newbin ${myprog} ${PN}-$(basename ${myprog})
elog "${myprog} installed as ${PN}-$(basename ${myprog})"
done
# bug 477384
dobashcomp conf/bash-completion/completions/mosh
}
|
GitWeb
