blob: eb3d31cb1f35304b7009bd2f1d0b7226ccf719e3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6,7} )
inherit cmake python-single-r1 xdg-utils
if [[ ${PV} == *9999* ]]; then
EGIT_REPO_URI="git://sigrok.org/${PN}"
inherit git-r3
else
SRC_URI="https://sigrok.org/download/source/${PN}/${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
fi
DESCRIPTION="Qt based logic analyzer GUI for sigrok"
HOMEPAGE="https://sigrok.org/wiki/PulseView"
LICENSE="GPL-3"
SLOT="0"
IUSE="+decode static"
REQUIRED_USE="decode? ( ${PYTHON_REQUIRED_USE} )"
BDEPEND="
dev-qt/linguist-tools:5
virtual/pkgconfig
"
RDEPEND="
>=dev-cpp/glibmm-2.28.0:2
>=dev-libs/boost-1.55:=
>=dev-libs/glib-2.28.0:2
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtsvg:5
dev-qt/qtwidgets:5
>=sci-libs/libsigrok-0.6.0:=[cxx]
decode? (
${PYTHON_DEPS}
>=sci-libs/libsigrokdecode-0.6.0:=[${PYTHON_SINGLE_USEDEP}]
)
"
DEPEND="${RDEPEND}"
DOCS=( HACKING NEWS README )
pkg_setup() {
use decode && python_setup
}
src_prepare() {
cmake_src_prepare
cmake_comment_add_subdirectory manual
}
src_configure() {
local mycmakeargs=(
-DDISABLE_WERROR=TRUE
-DENABLE_DECODE=$(usex decode)
-DSTATIC_PKGDEPS_LIBS=$(usex static)
)
cmake_src_configure
}
pkg_postinst() {
xdg_icon_cache_update
xdg_desktop_database_update
}
pkg_postrm() {
xdg_icon_cache_update
xdg_desktop_database_update
}
|
GitWeb
