sys-block/sedutil/sedutil-1.15.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit toolchain-funcs

DESCRIPTION="The Drive Trust Alliance Self Encrypting Drive Utility"
HOMEPAGE="https://github.com/Drive-Trust-Alliance/sedutil"
SRC_URI="https://github.com/Drive-Trust-Alliance/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

src_prepare() {
	default
	# https://github.com/Drive-Trust-Alliance/sedutil/pull/49
	find -name '*.mk' -exec sed -E -i 's: -(Werror|g|O[0-9]?) : :g' {} + || die
}

src_configure() {
	case $(tc-arch) in
		x86)   sedutil_arch="Release_i686" ;;
		amd64) sedutil_arch="Release_x86_64" ;;
		*)     die "unsupported architecture" ;;
	esac
}

src_compile() {
	emake \
		-C "linux/CLI" \
		V=1 \
		CONF="${sedutil_arch}" \
		CC="$(tc-getCC)" \
		CXX="$(tc-getCXX)" \
		CFLAGS="${CFLAGS}" \
		CXXFLAGS="${CXXFLAGS}"
}

src_install() {
	dobin "linux/CLI/dist/${sedutil_arch}/GNU-Linux/sedutil-cli"
	dodoc README.md
}