blob: ab46bff8890cd41582912a2526208ff0c4fd346f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
USE_RUBY="ruby22"
inherit ruby-fakegem
RUBY_FAKEGEM_EXTRADOC="README.markdown History.markdown"
RUBY_FAKEGEM_EXTRAINSTALL="features"
RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
RUBY_FAKEGEM_BINDIR="exe"
DESCRIPTION="A simple, blog aware, static site generator"
HOMEPAGE="http://jekyllrb.com https://github.com/jekyll/jekyll"
SRC_URI="https://github.com/jekyll/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="test"
ruby_add_rdepend "
>=dev-ruby/addressable-2.4
>=dev-ruby/colorator-1.0
>=dev-ruby/kramdown-1.14
>=dev-ruby/liquid-4.0:4
>=dev-ruby/mercenary-0.3.3
>=dev-ruby/pathutil-0.9
>=dev-ruby/safe_yaml-1.0
>=dev-ruby/rouge-1.7:0
>=www-apps/jekyll-sass-converter-1.0
>=www-apps/jekyll-watch-1.1
"
ruby_add_bdepend "
test? (
>=dev-ruby/classifier-reborn-2.1.0
dev-ruby/launchy
>=dev-ruby/pygments_rb-0.6.0
>=dev-ruby/rdiscount-2.0
>=dev-ruby/redcarpet-3.2.3
dev-ruby/rspec-mocks
>=dev-ruby/shoulda-3
dev-ruby/test-unit:2
www-apps/jekyll-coffeescript
)
"
all_ruby_prepare() {
eapply "${FILESDIR}"/jekyll-3.6.0-test-helper.patch
# Drop tests requiring bundler
sed -i -e '/bundle_message/d' test/test_new_command.rb || die
rm test/test_plugin_manager.rb || die
# Replace git command in gemspec
sed -i 's/git ls-files -z/find -not -type d -print0/' $RUBY_FAKEGEM_GEMSPEC || die
# FIXMEs:
# fails to find fixtures
rm test/test_theme.rb || die
rm test/test_theme_assets_reader.rb || die
sed -i -e '/^ should.*theme/,/^ end$/d' \
-e '/^ should.*theme/,/^ end$/d' test/test_site.rb || die
# partially requires 'toml'
rm test/test_configuration.rb || die
# pygments tests fail because of line numbering
sed -i -e '/^ context.*pygments/,/^ end$/d' test/test_tags.rb || die
sed -i -e '/^ context.*pygments/,/^ end$/d' test/test_redcarpet.rb || die
}
src_test() {
local -x JEKYLL_NO_BUNDLER_REQUIRE=true
ruby-ng_src_test
}
|
GitWeb