x11-apps/radeon-profile/radeon-profile-99999999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit qmake-utils

DESCRIPTION="Read current clocks of ATi/AMD Radeon cards"
HOMEPAGE="https://github.com/marazmista/radeon-profile"
if [[ "${PV}" == 99999999 ]] ; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/marazmista/radeon-profile.git"
else
	SRC_URI="https://github.com/marazmista/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-2"
SLOT="0"

IUSE=""

S="${WORKDIR}/${P}/${PN}"

RDEPEND="
	dev-qt/qtcharts:5
	dev-qt/qtcore:5
	dev-qt/qtgui:5
	dev-qt/qtnetwork:5
	dev-qt/qtwidgets:5
	x11-libs/libX11
	x11-libs/libXrandr
"

DEPEND="
	${RDEPEND}
	dev-qt/qtconcurrent:5
	media-libs/mesa
	x11-libs/libdrm
"

src_prepare() {
	default
	sed 's@TrayIcon;@@' -i extra/${PN}.desktop || die
}

src_configure() {
	eqmake5
}

src_install() {
	emake INSTALL_ROOT="${D}" install
}

pkg_postinst() {
	elog "In order to run ${PN} as non-root user, the"
	elog "  x11-apps/radeon-profile-daemon"
	elog "package needs to be installed and the daemon must run."
}