wine-1.7.26-r3 - add pulseaudio support

Thanks okias!

2 files changed, 478 insertions, 0 deletions

diff --git a/app-emulation/wine/Manifest b/app-emulation/wine/Manifest
index 59fafaa..bf051db 100644
--- a/app-emulation/wine/Manifest
+++ b/app-emulation/wine/Manifest
@@ -13,6 +13,7 @@ DIST wine-1.7.19.tar.bz2 21633142 SHA256 c5ea9b00c9029ecf47a25881b284d8ea02079df
 DIST wine-1.7.21.tar.bz2 21635330 SHA256 a14723104135c21414c61e146144a2c527430057255f8c35a3a7d354e68b9401 SHA512 73db3256d04c681ea7a4524767f9f93c24a4cc96aa901c6fdfd700c7e8968cdb127a110df56f10423cac90aadc783ceafcd0dc571e36ea096c1de03c619164d8 WHIRLPOOL 32bcf10f8665dab43339e79240b534f3fa29087787acd752553b4b717f6c26f8e98d36185f61e928e2c5ef9a3663b9eac7ec42cd9898800ba12efab74c78634c
 DIST wine-1.7.26.tar.bz2 21708411 SHA256 e20c7c26a3bd887afac655a274335923ae7ccf4053383e4edbb0c290aadb5de8 SHA512 4203959776f0977999fa9e1751515207fb4292b3c35b755ed7c68d53f179aabfba997fea5c3fdf9abe2c7fe21aeba364173f60c0666e7603c75d470a855b1ca7 WHIRLPOOL eb8aeb70aca2598b03a6d374b0a8d00e18862469259f25b4441b3bf65d234a53ec04cbe183bb70f1232e9663714fc3517c9882b2e4ef9b359bf9a468472dfa57
 DIST wine-1.7.8.tar.bz2 21463503 SHA256 30e17f5f863a09416f3d229666566b318dbb40f683d4ca6630012c60bb511804 SHA512 1fdaddb7909f818050854bf351d20f445cf6a5906b1bcc789c96ee8d5058c90815a91bbbc6444f3e4527748764f03ab5297585c174b433093a3354a827402fea WHIRLPOOL 3b5b18384ff04b80b936160c2c6e03676d69663c023f484981305c9272d0601b74cda5c5f7d56008b3900d702b1a4fe1929f16b1fba304a6480b076ffede663a
+DIST wine-compholio-1.7.26.tar.gz 8358571 SHA256 e1b9bba860467fa0914d804e07f99ce0491f3f21cc6e1c061674a7667093d751 SHA512 27356891a97e577cfa4ec945304523e91851e9384d19ba480cd2f951fc419f615adf4a680caba0d7898cca2875f47621210a30199f227e68083babfae89ace82 WHIRLPOOL 4dac17167378ac8f4eedb50ea7d6521bfa80e0578d07b7bbdf11b10fbd620308681992b3369dc9920e5e6445be2415b606485dbf44103393443e04fda40c714e
 DIST wine-compholio-daily-1.7.18-1.tar.gz 874844 SHA256 3b42267d2e8b06895cbd16b1941d933efa6d1c01f0a396a12dedbbfb3be4a41f SHA512 d33aed231c64e713967770e2b118fde03b14b6e32cea42037c4940ea9bdacfec2299e9253fe4cb67d557e77d695d5e3ad8363b2c7c8ab788e5e8914bb2102a06 WHIRLPOOL 5997677575dfd9823e6e14f0d4e668ccbf6b75a555e33692c1b986629f438271821c3d68de684202e9cf67d044643577cb63f46645e17386017afb6a68c0add1
 DIST wine-compholio-daily-1.7.21.tar.gz 883807 SHA256 19b619599e1d00829ab7782e069551dede0feacfd918b168f0843bd4ab0cd0d2 SHA512 a6df3792121dae2eceebf9ae3bb05f124ce70fbc8261b79152f16c9f22478a54bec2432eba6c38c6b70188efd3ed488a8199a4c5aa9416919dc4b465f564330f WHIRLPOOL 3b4cc5ac373420f0c26d745618a5445e45b547a4f4b851d5113c9f280251d220130b3c38779f534ea9c7caed03f8c73b70837033c9042da18e33e976349a241d
 DIST wine-gentoo-2012.11.24.tar.bz2 57481 SHA256 164248d7ff8cf06053576a3ecc1f6fe88a52763b04058ae53a9a4d5cfb6e7e22 SHA512 2a626ccbd408204dc6d1710ebb524a7961f4f417abc4cf1b65b4954a7b3033592febc8e9886ab47b000fc97dd3fe016a5833079f6bff84cd1d5aeb57a5167e07 WHIRLPOOL c638d0b0d8632d99f34cc4a294c4ddc7b69812af2ef536b3586fcfb41aab88a545d4c85c5a41020911dcb244eb7ed512cc6a957c6efd7ed06bd840f38e91f61d
diff --git a/app-emulation/wine/wine-1.7.26-r3.ebuild b/app-emulation/wine/wine-1.7.26-r3.ebuild
new file mode 100644
index 0000000..3a03714
--- /dev/null
+++ b/app-emulation/wine/wine-1.7.26-r3.ebuild
@@ -0,0 +1,477 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+
+AUTOTOOLS_AUTORECONF=1
+PLOCALES="ar bg ca cs da de el en en_US eo es fa fi fr he hi hr hu it ja ko lt ml nb_NO nl or pa pl pt_BR pt_PT rm ro ru sk sl sr_RS@cyrillic sr_RS@latin sv te th tr uk wa zh_CN zh_TW"
+PLOCALE_BACKUP="en"
+
+inherit autotools-utils eutils fdo-mime flag-o-matic gnome2-utils l10n multilib multilib-minimal pax-utils toolchain-funcs virtualx
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://source.winehq.org/git/wine.git"
+	inherit git-2
+	SRC_URI=""
+	#KEYWORDS=""
+else
+	MY_P="${PN}-${PV/_/-}"
+	SRC_URI="mirror://sourceforge/${PN}/Source/${MY_P}.tar.bz2"
+	KEYWORDS="-* ~amd64" # ~x86 ~x86-fbsd
+	S=${WORKDIR}/${MY_P}
+fi
+
+GV="2.24"
+MV="4.5.2"
+DESCRIPTION="Free implementation of Windows(tm) on Unix"
+HOMEPAGE="http://www.winehq.org/"
+SRC_URI="${SRC_URI}
+	gecko? (
+		abi_x86_32? ( mirror://sourceforge/${PN}/Wine%20Gecko/${GV}/wine_gecko-${GV}-x86.msi )
+		abi_x86_64? ( mirror://sourceforge/${PN}/Wine%20Gecko/${GV}/wine_gecko-${GV}-x86_64.msi )
+	)
+	mono? ( mirror://sourceforge/${PN}/Wine%20Mono/${MV}/wine-mono-${MV}.msi )
+	pulseaudio? ( http://github.com/compholio/wine-compholio/archive/v${PV}.tar.gz -> wine-compholio-${PV}.tar.gz )
+	"
+
+LICENSE="LGPL-2.1"
+SLOT=${PV}
+IUSE="+abi_x86_32 +abi_x86_64 +alsa capi cups custom-cflags dos elibc_glibc +fontconfig +gecko gphoto2 gsm +jpeg lcms ldap +mono mp3 +multislot ncurses netapi nls odbc openal opencl +opengl osmesa oss +perl +png +prelink pulseaudio +realtime +run-exes samba scanner selinux +ssl swtor teso test +threads +truetype +udisks v4l +X xcomposite xinerama +xml"
+REQUIRED_USE="|| ( abi_x86_32 abi_x86_64 )
+	test? ( abi_x86_32 )
+	elibc_glibc? ( threads )
+	mono? ( abi_x86_32 )
+	osmesa? ( opengl )" #286560
+
+# FIXME: the test suite is unsuitable for us; many tests require net access
+# or fail due to Xvfb's opengl limitations.
+RESTRICT="test"
+
+NATIVE_DEPEND="
+	truetype? ( >=media-libs/freetype-2.0.0  )
+	capi? ( net-dialup/capi4k-utils )
+	ncurses? ( >=sys-libs/ncurses-5.2:= )
+	udisks? ( sys-apps/dbus )
+	fontconfig? ( media-libs/fontconfig:= )
+	gphoto2? ( media-libs/libgphoto2:= )
+	openal? ( media-libs/openal:= )
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libXext
+		x11-libs/libXrandr
+		x11-libs/libXi
+		x11-libs/libXxf86vm
+	)
+	xinerama? ( x11-libs/libXinerama )
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups:= )
+	opencl? ( virtual/opencl )
+	opengl? (
+		virtual/glu
+		virtual/opengl
+	)
+	gsm? ( media-sound/gsm:= )
+	jpeg? ( virtual/jpeg:0= )
+	ldap? ( net-nds/openldap:= )
+	lcms? ( media-libs/lcms:2= )
+	mp3? ( >=media-sound/mpg123-1.5.0 )
+	netapi? ( net-fs/samba[netapi(+)] )
+	nls? ( sys-devel/gettext )
+	odbc? ( dev-db/unixODBC:= )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-sound/pulseaudio )
+	xml? ( dev-libs/libxml2 dev-libs/libxslt )
+	scanner? ( media-gfx/sane-backends:= )
+	ssl? ( net-libs/gnutls:= )
+	png? ( media-libs/libpng:0= )
+	v4l? ( media-libs/libv4l )
+	xcomposite? ( x11-libs/libXcomposite )"
+
+COMMON_DEPEND="
+	!amd64? ( ${NATIVE_DEPEND} )
+	amd64? (
+		abi_x86_64? ( ${NATIVE_DEPEND} )
+		abi_x86_32? (
+			truetype? ( || (
+				>=app-emulation/emul-linux-x86-xlibs-2.1[development,-abi_x86_32(-)]
+				>=media-libs/freetype-2.5.0.1[abi_x86_32(-)]
+			) )
+			ncurses? ( || (
+				app-emulation/emul-linux-x86-baselibs[development,-abi_x86_32(-)]
+				>=sys-libs/ncurses-5.9-r3[abi_x86_32(-)]
+			) )
+			udisks? ( || (
+				>=app-emulation/emul-linux-x86-baselibs-20130224[development,-abi_x86_32(-)]
+				>=sys-apps/dbus-1.6.18-r1[abi_x86_32(-)]
+			) )
+			fontconfig? ( || (
+				app-emulation/emul-linux-x86-xlibs[development,-abi_x86_32(-)]
+				>=media-libs/fontconfig-2.10.92[abi_x86_32(-)]
+			) )
+			gphoto2? ( || (
+				app-emulation/emul-linux-x86-medialibs[development,-abi_x86_32(-)]
+				>=media-libs/libgphoto2-2.5.3.1[abi_x86_32(-)]
+			) )
+			openal? ( || (
+				app-emulation/emul-linux-x86-sdl[development,-abi_x86_32(-)]
+				>=media-libs/openal-1.15.1[abi_x86_32(-)]
+			) )
+			X? ( || (
+				app-emulation/emul-linux-x86-xlibs[development,-abi_x86_32(-)]
+				(
+					>=x11-libs/libXcursor-1.1.14[abi_x86_32(-)]
+					>=x11-libs/libXext-1.3.2[abi_x86_32(-)]
+					>=x11-libs/libXrandr-1.4.2[abi_x86_32(-)]
+					>=x11-libs/libXi-1.7.2[abi_x86_32(-)]
+					>=x11-libs/libXxf86vm-1.1.3[abi_x86_32(-)]
+				)
+			) )
+			xinerama? ( || (
+				app-emulation/emul-linux-x86-xlibs[development,-abi_x86_32(-)]
+				>=x11-libs/libXinerama-1.1.3[abi_x86_32(-)]
+			) )
+			alsa? ( || (
+				app-emulation/emul-linux-x86-soundlibs[alsa,development,-abi_x86_32(-)]
+				>=media-libs/alsa-lib-1.0.27.2[abi_x86_32(-)]
+			) )
+			cups? ( || (
+				app-emulation/emul-linux-x86-baselibs
+				>=net-print/cups-1.7.1-r1[abi_x86_32(-)]
+			) )
+			opencl? ( >=virtual/opencl-0-r3[abi_x86_32(-)] )
+			opengl? ( || (
+				app-emulation/emul-linux-x86-opengl[development,-abi_x86_32(-)]
+				(
+					>=virtual/glu-9.0-r1[abi_x86_32(-)]
+					>=virtual/opengl-7.0-r1[abi_x86_32(-)]
+				)
+			) )
+			gsm? ( || (
+				app-emulation/emul-linux-x86-soundlibs[development,-abi_x86_32(-)]
+				>=media-sound/gsm-1.0.13-r1[abi_x86_32(-)]
+			) )
+			jpeg? ( || (
+				app-emulation/emul-linux-x86-baselibs[development,-abi_x86_32(-)]
+				>=virtual/jpeg-0-r2:0[abi_x86_32(-)]
+			) )
+			ldap? ( || (
+				app-emulation/emul-linux-x86-baselibs[development,-abi_x86_32(-)]
+				>=net-nds/openldap-2.4.38-r1:=[abi_x86_32(-)]
+			) )
+			lcms? ( || (
+				app-emulation/emul-linux-x86-baselibs[development,-abi_x86_32(-)]
+				>=media-libs/lcms-2.5:2[abi_x86_32(-)]
+			) )
+			mp3? ( || (
+				app-emulation/emul-linux-x86-soundlibs[development,-abi_x86_32(-)]
+				>=media-sound/mpg123-1.15.4[abi_x86_32(-)]
+			) )
+			netapi? ( >=net-fs/samba-3.6.23-r1[netapi(+),abi_x86_32(-)] )
+			nls? ( || (
+				app-emulation/emul-linux-x86-baselibs[development,-abi_x86_32(-)]
+				>=sys-devel/gettext-0.18.3.2[abi_x86_32(-)]
+			) )
+			odbc? ( || (
+				app-emulation/emul-linux-x86-db[development,-abi_x86_32(-)]
+				>=dev-db/unixODBC-2.3.2:=[abi_x86_32(-)]
+			) )
+			osmesa? ( || (
+				>=app-emulation/emul-linux-x86-opengl-20121028[development,-abi_x86_32(-)]
+				>=media-libs/mesa-9.1.6[osmesa,abi_x86_32(-)]
+			) )
+			pulseaudio? ( || (
+				app-emulation/emul-linux-x86-soundlibs[development,-abi_x86_32(-)]
+				>=media-sound/pulseaudio-5.0[abi_x86_32(-)]
+			) )
+			xml? ( || (
+				>=app-emulation/emul-linux-x86-baselibs-20131008[development,-abi_x86_32(-)]
+				(
+					>=dev-libs/libxml2-2.9.1-r4[abi_x86_32(-)]
+					>=dev-libs/libxslt-1.1.28-r1[abi_x86_32(-)]
+				)
+			) )
+			scanner? ( || (
+				app-emulation/emul-linux-x86-medialibs[development,-abi_x86_32(-)]
+				>=media-gfx/sane-backends-1.0.23:=[abi_x86_32(-)]
+			) )
+			ssl? ( || (
+				app-emulation/emul-linux-x86-baselibs[development,-abi_x86_32(-)]
+				>=net-libs/gnutls-2.12.23-r6:=[abi_x86_32(-)]
+			) )
+			png? ( || (
+				app-emulation/emul-linux-x86-baselibs[development,-abi_x86_32(-)]
+				>=media-libs/libpng-1.6.10:0[abi_x86_32(-)]
+			) )
+			v4l? ( || (
+				app-emulation/emul-linux-x86-medialibs[development,-abi_x86_32(-)]
+				>=media-libs/libv4l-0.9.5[abi_x86_32(-)]
+			) )
+			xcomposite? ( || (
+				app-emulation/emul-linux-x86-xlibs[development,-abi_x86_32(-)]
+				>=x11-libs/libXcomposite-0.4.4-r1[abi_x86_32(-)]
+			) )
+		)
+	)"
+
+RDEPEND="${COMMON_DEPEND}
+	multislot? ( app-admin/eselect-wine )
+	!multislot? ( !<${CATEGORY}/${PF}
+		!>${CATEGORY}/${PF} )
+	dos? ( games-emulation/dosbox )
+	perl? ( dev-lang/perl dev-perl/XML-Simple )
+	samba? ( >=net-fs/samba-3.0.25 )
+	selinux? ( sec-policy/selinux-wine )
+	udisks? ( sys-fs/udisks:2 )
+	pulseaudio? ( realtime? ( sys-auth/rtkit ) )
+	"
+
+DEPEND="${COMMON_DEPEND}
+	amd64? ( abi_x86_32? ( !abi_x86_64? ( ${NATIVE_DEPEND} ) ) )
+	X? (
+		x11-proto/inputproto
+		x11-proto/xextproto
+		x11-proto/xf86vidmodeproto
+	)
+	xinerama? ( x11-proto/xineramaproto )
+	prelink? ( sys-devel/prelink )
+	>=sys-kernel/linux-headers-2.6
+	virtual/pkgconfig
+	virtual/yacc
+	sys-devel/flex"
+
+wine_build_environment_check() {
+	[[ ${MERGE_TYPE} = "binary" ]] && return 0
+
+	if use abi_x86_64 && [[ $(( $(gcc-major-version) * 100 + $(gcc-minor-version) )) -lt 404 ]]; then
+		eerror "You need gcc-4.4+ to build 64-bit wine"
+		eerror
+		return 1
+	fi
+
+	if use abi_x86_32 && use opencl && [[ x$(eselect opencl show 2> /dev/null) = "xintel" ]]; then
+		eerror "You cannot build wine with USE=opencl because intel-ocl-sdk is 64-bit only."
+		eerror "See https://bugs.gentoo.org/487864 for more details."
+		eerror
+		return 1
+	fi
+}
+
+pkg_pretend() {
+	wine_build_environment_check || die
+}
+
+pkg_setup() {
+	if use multislot; then
+		MY_PREFIX=/usr/lib/wine-${SLOT}
+		MY_DATADIR=${MY_PREFIX}
+	else
+		MY_PREFIX=/usr
+		MY_DATADIR=${MY_PREFIX}/share
+	fi
+	wine_build_environment_check || die
+}
+
+src_unpack() {
+	if [[ ${PV} == "9999" ]] ; then
+		git-2_src_unpack
+	else
+		unpack ${MY_P}.tar.bz2
+	fi
+
+	if use pulseaudio; then
+		unpack wine-compholio-${PV}.tar.gz
+	fi
+
+	l10n_find_plocales_changes "${S}/po" "" ".po"
+}
+
+src_prepare() {
+	local md5="$(md5sum server/protocol.def)"
+	local f
+	local PATCHES=(
+		"${FILESDIR}"/${PN}-1.5.26-winegcc.patch #260726
+		"${FILESDIR}"/${PN}-1.4_rc2-multilib-portage.patch #395615
+		"${FILESDIR}"/${PN}-1.7.12-osmesa-check.patch #429386
+		"${FILESDIR}"/${PN}-1.6-memset-O3.patch #480508
+	)
+	# http://bugs.winehq.org/show_bug.cgi?id=29168
+	use swtor && PATCHES+=(
+		"${FILESDIR}"/${PN}-1.7.1-KUSER_SHARED_DATA_18.patch
+	)
+	# http://bugs.winehq.org/show_bug.cgi?id=34388
+	use teso && PATCHES+=(
+		"${FILESDIR}"/${PN}-1.7.2-crypt32-Skip-unknown-item-when.patch
+	)
+	# bug #421365
+	use pulseaudio && PATCHES+=(
+		"${WORKDIR}"/wine-compholio-${PV}/patches/winepulse-PulseAudio_Support/*.patch
+	)
+	autotools-utils_src_prepare
+
+	if [[ "$(md5sum server/protocol.def)" != "${md5}" ]]; then
+		einfo "server/protocol.def was patched; running tools/make_requests"
+		tools/make_requests || die #432348
+	fi
+	sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in || die
+	if ! use run-exes; then
+		sed -i '/^MimeType/d' tools/wine.desktop || die #117785
+	fi
+
+	if use multislot; then
+		sed -e "/^Exec=/s/wine /wine-${SLOT} /" \
+			-i tools/wine.desktop || die
+	fi
+
+	l10n_get_locales > po/LINGUAS # otherwise wine doesn't respect LINGUAS
+}
+
+src_configure() {
+	export LDCONFIG=/bin/true
+	use custom-cflags || strip-flags
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	local myconf=()
+	if use multislot; then
+		myconf+=(
+			--prefix="${MY_PREFIX}"
+			--datadir="${MY_DATADIR}"
+			--mandir="${MY_DATADIR}"/man
+		)
+	fi
+	myconf+=(
+		--sysconfdir=/etc/wine
+		$(use_with alsa)
+		$(use_with capi)
+		$(use_with lcms cms)
+		$(use_with cups)
+		$(use_with ncurses curses)
+		$(use_with udisks dbus)
+		$(use_with fontconfig)
+		$(use_with ssl gnutls)
+		$(use_with gphoto2 gphoto)
+		$(use_with gsm)
+		--without-gstreamer
+		--without-hal
+		$(use_with jpeg)
+		$(use_with ldap)
+		$(use_with mp3 mpg123)
+		$(use_with netapi)
+		$(use_with nls gettext)
+		$(use_with openal)
+		$(use_with opencl)
+		$(use_with opengl)
+		$(use_with osmesa)
+		$(use_with oss)
+		$(use_with png)
+		--without-pcap
+		$(use_with threads pthread)
+		$(use_with scanner sane)
+		$(use_enable test tests)
+		$(use_with truetype freetype)
+		$(use_with v4l)
+		$(use_with X x)
+		$(use_with xcomposite)
+		$(use_with xinerama)
+		$(use_with xml)
+		$(use_with xml xslt)
+	)
+
+	use pulseaudio && myconf+=( --with-pulse )
+
+	local PKG_CONFIG AR RANLIB
+	# Avoid crossdev's i686-pc-linux-gnu-pkg-config if building wine32 on amd64; #472038
+	# set AR and RANLIB to make QA scripts happy; #483342
+	tc-export PKG_CONFIG AR RANLIB
+
+	if use amd64; then
+		if [[ ${ABI} == amd64 ]]; then
+			myconf+=( --enable-win64 )
+		else
+			myconf+=( --disable-win64 )
+		fi
+
+		# Note: using --with-wine64 results in problems with multilib.eclass
+		# CC/LD hackery. We're using separate tools instead.
+	fi
+
+	ECONF_SOURCE=${S} \
+	econf "${myconf[@]}"
+	emake depend
+}
+
+multilib_src_test() {
+	# FIXME: win32-only; wine64 tests fail with "could not find the Wine loader"
+	if [[ ${ABI} == x86 ]]; then
+		if [[ $(id -u) == 0 ]]; then
+			ewarn "Skipping tests since they cannot be run under the root user."
+			ewarn "To run the test ${PN} suite, add userpriv to FEATURES in make.conf"
+			return
+		fi
+
+		WINEPREFIX="${T}/.wine-${ABI}" \
+		Xemake test
+	fi
+}
+
+multilib_src_install_all() {
+	local DOCS=( ANNOUNCE AUTHORS README )
+	local l
+	add_locale_docs() {
+		local locale_doc="documentation/README.$1"
+		[[ ! -e ${locale_doc} ]] || DOCS+=( ${locale_doc} )
+	}
+	l10n_for_each_locale_do add_locale_docs
+
+	einstalldocs
+	prune_libtool_files --all
+
+	if use gecko ; then
+		insinto "${MY_DATADIR}"/wine/gecko
+		use abi_x86_32 && doins "${DISTDIR}"/wine_gecko-${GV}-x86.msi
+		use abi_x86_64 && doins "${DISTDIR}"/wine_gecko-${GV}-x86_64.msi
+	fi
+	if use mono ; then
+		insinto "${MY_DATADIR}"/wine/mono
+		doins "${DISTDIR}"/wine-mono-${MV}.msi
+	fi
+	if ! use perl ; then
+		rm "${D%/}${MY_PREFIX}"/bin/{wine{dump,maker},function_grep.pl} "${D%/}${MY_DATADIR}"/man/man1/wine{dump,maker}.1 || die
+	fi
+
+	use abi_x86_32 && pax-mark psmr "${D%/}${MY_PREFIX}"/bin/wine{,-preloader} #255055
+	use abi_x86_64 && pax-mark psmr "${D%/}${MY_PREFIX}"/bin/wine64{,-preloader}
+
+	if use abi_x86_64 && ! use abi_x86_32; then
+		dosym "${MY_PREFIX}"/bin/wine{64,} # 404331
+		dosym "${MY_PREFIX}"/bin/wine{64,}-preloader
+	fi
+
+	if use multislot; then
+		for b in "${D%/}${MY_PREFIX}"/bin/*; do
+			make_wrapper ${b##*/}-${SLOT} "${MY_PREFIX}"/bin/${b##*/}
+		done
+	fi
+
+	# respect LINGUAS when installing man pages, #469418
+	for l in de fr pl; do
+		use linguas_${l} || rm -r "${D%/}${MY_DATADIR}"/man/${l}*
+	done
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}